Doevents函數(shù)是一個很好用的函數(shù)，但很多人對它的用法不清楚或有誤解。由于我在網(wǎng)上查到一篇關于此函數(shù)的用法，并添加了一些內(nèi)容，不敢獨享，特此獻出。
    其中有一個“控時循環(huán)和變速齒輪”的內(nèi)容，有點意思，感興趣的可看一看。

    DoEvents函數(shù)的功能是：轉(zhuǎn)讓控制權(quán)，以便讓操作系統(tǒng)處理其它的事件。
    問:為什么要用doevents?
     A.在需要用某一循環(huán)處理相當耗時或者很快速的代碼時,就需要用到它,以便用戶能在起處理過程中能做其他事情,即程序能被控制,而不是無響應狀態(tài)
     B.vb6.0中多線程vb代碼極度不穩(wěn)定,而且無法調(diào)試,所以vb中的多線程用的很少(注:是指vb的代碼在多線程中運行時不穩(wěn)定)
     C.timer控件可以起到后臺運行作用,但其是通過事件控制,一是不穩(wěn)定,二是速度太慢,如果想用其處理高速又耗系統(tǒng)的代碼更本不能達到預期的效果

下面將其某些用法和難點簡介如下:
     
    (注: 1.'** 后面的代碼表示如果在該處用了這個語句。2.例子中會用到API函數(shù)。3.以下例子都經(jīng)vb6.0測試成功）
     
一. 基本用法:
    1.窗體啟動時如果要處理的事務太多或者用sleep函數(shù)暫停,造成其很久都不能出現(xiàn)時怎么辦?
    例如代碼:
    Public Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)'此句寫入模塊
    Private Sub Form_Load()
    Show
    '**DoEvents  句3
    Sleep 5000
    End Sub
    通常容易想到在sleep前加個show,但還是不能達到預想的效果,窗體雖然出來了,但好象只達到了一半,如果加上第3句,將看到效果大不相同 。

    2.如果有個很耗時的循環(huán)導致程序不響應,怎么辦?
    例如:
    Dim L As Long
    For L = 1 To 1000000
    '** DoEvents
    Next L
    如果無'**,在循環(huán)過程中程序無法處理事件,對于用戶來說是不響應,無法控制的

    3.想在循環(huán)中看到處理過程?
    同樣:
    Dim L As Long
    For L = 1 To 10000
    '** DoEvents
    Text1.Text=Cstr(l)
    Next L
    無'** 時將無法看到text1中的變化,而只在循環(huán)結(jié)束時看到最后結(jié)果

    4.怎樣中止循環(huán)?
    如果有:
    Private Sub Command1_Click()
    Dim L As Long
    Do
     L = L + 1
     Debug.Print L  '在立即窗口中顯示
     DoEvents
    Loop
    End Sub
    會發(fā)現(xiàn)當關閉窗口后,debug中的數(shù)據(jù)仍然在變化,說明并沒結(jié)束
    需要如下:
    Dim IsExit As Boolean
    Private Sub Command1_Click()
    Dim L As Long
     IsExit = False
     Do While DoEvents
     If IsExit = True Then Exit Do
     L = L + 1
     Loop
    End Sub
     
    Private Sub Command2_Click()'或者在form_unload模塊中等等
     IsExit = True
    End Sub
    其中 isexit是全局變量
    <>有些人喜歡用end語句來結(jié)束程序,小程序固然可以,但當太大,或者調(diào)用了某些特殊的api函數(shù)后可能導致預想不到的錯誤,如果裝載了許多東西在程序結(jié)束時不處理將卸載很慢,而且這種做法也極不符合正規(guī)軟件的要求...總之end語句毛病很多,此不詳談,建議少使用甚至不使用

二. 其基本用法大概就這些,現(xiàn)在解析其中的一些[難點]
     
    1.為什么還是不能結(jié)束?
    代碼如下:
    Dim IsExit As Boolean
    Private Sub Command1_Click()
    Dim L As Long
     IsExit = False
     Do
     If IsExit = True Then Exit Do '句0
     DoEvents '** 句1
     Text1.Text = CStr(L) '** 句2
     L = L + 1
     Loop
    End Sub
     
    Private Sub Form_Load()
    Static N As Long
    N = N + 1
    MsgBox N
    End Sub
     
    Private Sub Form_Unload(Cancel As Integer)
     IsExit = True
    End Sub
     
    運行結(jié)果:啟動時msg顯示1,點擊command1,text1在變化，此時再點form右上角的小差(關閉窗體),發(fā)現(xiàn)vb運行控制上的按扭并沒變化,說明程序還在運行.如果編譯成程序后運行,按下ctrl+del+alt也可發(fā)現(xiàn)它還沒結(jié)束.
    通過讀代碼,并沒發(fā)現(xiàn)錯誤，怎么回事?
    關鍵在于"句2"訪問了控件的屬性 ：
    代碼運行路徑:當在doevents 時,程序釋放控制權(quán),可以接收事件消息,form-unload事件只能從此處產(chǎn)生,假設此時關閉form ,unload事件發(fā)生,即doevents后就運行unload代碼,得到isexit=t,并且form卸載,代碼返回到doevents 之后,運行句2.注意現(xiàn)在form 已經(jīng)卸載了,text1從哪里來呢? 于是form重新裝載,代碼跳到form_load模塊運行,所以在關閉窗體后可以看到msg 顯示2,此模塊運行完后再繼續(xù)句2后面的代碼,當下次循環(huán)遇到 句0時退出循環(huán)
    另:既然退出了循環(huán),怎么還不能結(jié)束?
    vb程序規(guī)定(其實其他的windows語言一樣):窗體卸載時并不是立即卸載其模塊代碼,而只先卸載窗體中的控件和一些屬性值,程序中最后一個窗體卸載時才完全卸載.
    在這個單窗體程序中,form卸載時因為循環(huán)的控制無法卸載代碼,失去了卸載代碼的機會,導致再也不能卸載(因為沒卸載代碼,所以運行的句2是并不會出錯) 。
    另:既然再次運行了form_load代碼,怎么看不見窗體?
    因為程序啟動時窗體的到顯示的消息,而只運行此模塊并沒有(如果在msgbox n語句前加上show,就可以看到它了)
    如何解決?
    通過以上分析,應該很簡單,把句1 和句2調(diào)換一下就可以了,關鍵:
    <仔細分析代碼是如何運行的,避免在form已經(jīng)卸載了情況下訪問控件>

    2.用了doevents速度太慢了怎么辦?
    doevents的代價是速度變慢,但要程序響應又不得不用，其實doevents語句允許任何應用程序執(zhí)行相關事件，而不僅僅是你自己的程序,所以變得很慢.
    可以讓它響應本程序事件動作,需要用到api函數(shù)GetInputState，它的聲明語句為：
    Public Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)
    Public Declare Function GetInputState Lib "user32" () As Long
    例如用: If GetInputState() Then DoEvents '來代替doevents可使循環(huán)運行更快

    3.既要同時響應事件又要控件不變化,怎么辦?
    例如在一個長的循環(huán)中向listview控件中添加記錄,無doevents時程序無響應,但有它時控件又閃的厲害
    解決辦法:
    a.不一定每次循環(huán)都doevents,可以在適當時間時才用,至少沒那么閃
    b.應用api函數(shù) ValidateRect 功能是使指定的矩型區(qū)域生效,通知Windows不對指定的區(qū)域進行重畫 另:InvalidateRect 功能相反,同時需要用到函數(shù) GetClientRect 取得指定對象的矩形區(qū)域 應用*rect函數(shù)指定listview的矩形區(qū)不重畫,即可避免閃爍(但還是要注意恢復重畫,否則看不見了真實效果)

    4.控時循環(huán)和變速齒輪
    請看下面的代碼:
    Option Explicit
    Private Declare Function timeGetTime Lib "winmm.dll" () As Long
    Dim IsExit As Boolean
    Private Sub Command1_Click()
    Dim L As Long
    Dim Kt As Long
    IsExit = False
    Do
     Kt = timeGetTime()
     'do something
     L = L + 1
     Text1.Text = L
     'DoEvents '句 1
     While timeGetTime - Kt < 50 '句 2
     'While Abs(timeGetTime - Kt) < 50 '句 3
     'While Abs(timeGetTime - Kt) And (Not IsExit) < 50 '句 4
     
     DoEvents '句 5
     Wend
     'DoEvents '句 6
     If IsExit Then Exit Do
    Loop
    End Sub
     
    Private Sub Form_Unload(Cancel As Integer)
    IsExit = True
    End Sub
    其中可用的代碼(除去加"'" 號的代碼)就是通常的控時循環(huán)代碼
    運行代碼并不會出現(xiàn)錯誤,但在循環(huán)過程,請開啟變速齒輪看看
    當關閉齒輪時,將發(fā)現(xiàn)text1.text停止了,別慌,等一段時間它又會繼續(xù)(這要看你設定的時間,這里是50毫秒,如果設定的太長text1.text將半天都沒變化,這是怎么回事?
     變速齒輪在啟動時將hook.dll映射到你的程序地址運行,更改了timegettime()函數(shù)獲取的時間
    如果在句2和句3間插入debug.print timegettime,timegettime-kt 將發(fā)現(xiàn),在關閉齒輪的瞬間后者變成了負值,timegettime變小了,所以才造成需要等很久
    如果是編寫游戲,而用戶開了齒輪,那可就慘了
     
    解決方案:
    a.用句3代替句2,這個方法最簡便,雖然不符實,但不會出問題,建議使用
    b.不要句5,換用句6(這樣就能達到效果嗎?) 因為齒輪還是從doevents語句運行時才能插的進來,所以只要kt=timegettime 和 timegettime之間沒有doevents就不會出錯
    ab.兩種方法都有些小問題,但無大礙,有興趣者請自己分析

    5.程序怎么"死了"?
    這只是一些人編寫時沒注意到的小問題,提醒一下:
    同樣用上面的代碼,如果設定的時間太短,以至在代碼運行到句2時已經(jīng)超時了,句5將不能運行了,當然程序就死了哦,以防萬一,加上句1,所以此時也只能用a方案來解決齒輪的問題了
    有必要用句4代替句3 嗎? 除非你設定的時間太長,人家想關閉你的程序要等上好半天。

 在MSND上的內(nèi)容：在使用全局數(shù)據(jù)時避免 DoEvents
當一個函數(shù)已通過 DoEvents 放棄控制時，可相當安全地再次調(diào)用函數(shù)。例如，下一過程將檢測質(zhì)數(shù)并用 DoEvents 語句周期地啟動其它應用程序處理事件：

Function PrimeStatus (TestVal As Long) As Integer
   Dim Lim As Integer
   PrimeStatus = True
   Lim = Sqr(TestVal)
   For I = 2 To Lim
      If TestVal Mod I = 0 Then
         PrimeStatus = False
         Exit For
      End If
      If I Mod 200 = 0 Then DoEvents
   Next I
End Function

該代碼中每重復 200 次就調(diào)用一次 DoEvents 語句。這樣一來，當該環(huán)境的其余部分對事件作出響應時，只要有必要，PrimeStatus 過程就可繼續(xù)計算。

考慮在調(diào)用 DoEvents 期間發(fā)生的事情。在其它窗體和應用程序處理事件時將暫停執(zhí)行應用程序代碼。這些事件之一有可能是一個按鈕單擊操作，它將再次啟動 PrimeStatus 過程。

這將導致重新進入 PrimeStatus 過程的，但是，因為在函數(shù)每次出現(xiàn)時，堆棧都為其參數(shù)和局部變量分配了空間，所以重入不會引發(fā)沖突。當然，如果過多調(diào)用 PrimeStatus，則可能出現(xiàn)“溢出堆?？臻g”錯誤。

如果 PrimeStatus 使用或改變模塊級變量或全局數(shù)據(jù)，情況就會完全不同。此時，在 DoEvents 能夠返回之前執(zhí)行 PrimeStatus 的另一個實例，這將導致模塊數(shù)據(jù)或全局數(shù)據(jù)的值完全不同于它們在調(diào)用 DoEvents 之前的值。于是，PrimeStatus 的結(jié)果將會難以預料。