Range對(duì)象的Insert方法可在工作表中插入一個(gè)單元格或單元格區(qū)域，其他單元格作相應(yīng)移動(dòng)以騰出空間。下面代碼在工作表的第2行插入單元格，原工作表的第2行單元格將占據(jù)第3行的位置。

　　Rows(2).Insert

　?。矗叮常保啊『喜^(qū)域與相交區(qū)域

　　Union方法返回Range對(duì)象，代表兩個(gè)或多個(gè)區(qū)域的合并區(qū)域，其參數(shù)為Range類(lèi)型。

　　Application.Union(Range("A3:D6"),Range("C5:F8"))

        Intersect方法返回Range對(duì)象，代表兩個(gè)或多個(gè)單元格區(qū)域重疊的矩形區(qū)域，其參數(shù)為Range類(lèi)型，如果參數(shù)單元格區(qū)域沒(méi)有重疊區(qū)域，那么結(jié)果為Nothing。

　　Application.Intersect(Range("A3:D6"),Range("C5:F8"))

　　利用 Intersect方法可以判斷某個(gè)單元格區(qū)域是否完全包含在另一個(gè)單元格區(qū)域中。

　　在Excel VBA中，事件是指對(duì)象可以辨認(rèn)的動(dòng)作。用戶(hù)可以指定VBA代碼來(lái)對(duì)這些動(dòng)作做出響應(yīng)。Excel可以監(jiān)視多種不同類(lèi)型的事件，Excel中的工作表、工作簿、應(yīng)用程序、圖表工作表、查詢(xún)表和控件等不同對(duì)象都有不同的事件，而且每個(gè)對(duì)象都有多種相關(guān)的事件，本章將主要介紹工作表和工作簿的常用事件。

　?。矗罚薄∈录^(guò)程

　　事件過(guò)程作為一種特殊的Sub過(guò)程，在事件被觸發(fā)時(shí)執(zhí)行，如果事件過(guò)程包含參數(shù)，系統(tǒng)會(huì)為相關(guān)參數(shù)賦值。事件過(guò)程必須寫(xiě)入相應(yīng)的模塊中才能發(fā)揮作用，工作簿事件過(guò)程須寫(xiě)入Thisworkbook模塊中，工作表事件過(guò)程則須寫(xiě)入相應(yīng)的工作表模塊中；且只有過(guò)程所在工作表的行為可以觸發(fā)該事件。

　　４７．２　工作表事件

　　工作表事件發(fā)生在特定的Worksheet對(duì)象中。Worksheet對(duì)象也是Excel最常用的對(duì)象之一，因此實(shí)際應(yīng)用中經(jīng)常會(huì)用到Worksheet對(duì)象事件。

　　４７．２．１　Change事件

　　工作表中的單元格被用戶(hù)手工修改或被ＶＢＡ代碼修改時(shí)，將觸發(fā)工作表Change事件。值得注意的是，雖然事件的名稱(chēng)是Change

但是并非工作表中單元格的任何變化都能觸發(fā)該事件。

　　Change事件的參數(shù)Target是Change變量，代表工作表中發(fā)生變化的區(qū)域，它可以是一個(gè)單元格也可以攻玉是多個(gè)單元格組成的區(qū)域。在實(shí)際應(yīng)用中，用戶(hù)通常希望只有工作表中的某些特定單元格區(qū)域發(fā)生變化時(shí)，才激活Change事件，這就需要在Change事件中對(duì)Target參數(shù)進(jìn)行判斷。

　　示例４７．１　自動(dòng)記錄數(shù)據(jù)錄入日期

　　在工作表ChangDemo的代碼窗口中寫(xiě)入如下代碼：

　　Private Sub Worksheet_Change(ByVal Target As Range)
    With Target
        '判斷是否選中了單個(gè)單元格
        If .Count = 1 Then
            '判斷單元格是否在第一列
            If .Column = 1 Then
                '禁止事件激活
                Application.EnableEvents = False
                '在相應(yīng)行的第二列輸入當(dāng)前日期
                Target.Offset(0, 1) = Date
                '恢復(fù)事件激活
                Application.EnableEvents = True
            End If
        End If
    End With
End Sub

　　返回Excel界面，在工作表ChangDemo中的A列中輸入備忘內(nèi)容，Change事件將自動(dòng)在B列的相應(yīng)行寫(xiě)入當(dāng)前日期。修改工作表中其他列的單元格（如C列），工作表的Change事件同樣會(huì)被觸發(fā)，但是因?yàn)椴粷M(mǎn)足代碼中的判斷條件，所以不會(huì)執(zhí)行寫(xiě)入日期的代碼。

　　如何禁止事件的激活

　　上述代碼使用Application.EnableEvents=False為防止事件被意外多次激活。Application對(duì)象的EnableEvents屬性可以設(shè)置是否允許對(duì)象的事件被激活。上述代碼中如果沒(méi)有禁止事件激活的代碼，在寫(xiě)入當(dāng)前日期的代碼執(zhí)行后，工作表的Change事件被再次激活，事件代碼被再次執(zhí)行。某些情況下，這種事件的意外激活會(huì)重復(fù)多次發(fā)生，甚至造成死循環(huán)導(dǎo)致事件代碼重復(fù)調(diào)用，無(wú)法結(jié)束運(yùn)行。因此在可能意外觸發(fā)事件的時(shí)候，需要設(shè)置Application.EnableEvents=False禁止事件激活。但這個(gè)設(shè)置并不能限制控件的事件被激活。

　　EnableEvents屬性的值不會(huì)隨著事件過(guò)程的執(zhí)行結(jié)束而自動(dòng)恢復(fù)為T(mén)rue，也就是說(shuō)需要在代碼運(yùn)行結(jié)束之前進(jìn)行恢復(fù)。如果代碼被異常終止，而EnableEvents屬性的值仍然為False，則相關(guān)的事件都無(wú)法激活?；謴?fù)辦法是在VBE的立即窗口中執(zhí)行Application.EnableEven

ts=True。

　?。矗罚玻病electionChange事件

　　工作表中選定區(qū)域的范圍發(fā)生變化將觸發(fā)工作表的SelectionChange事件。SelectionChange事件的參數(shù)Target是Range變量，代表工作青史被選中的區(qū)域，相當(dāng)于Selection屬性返回的Range對(duì)象。

　　示例４７．２　高亮顯示工作表中選定區(qū)域所在的行和列

　　在工作表SelectionChangeDemo中寫(xiě)入如下的SelectionChange事件代碼。

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    With Target
        '清除工作表單元格的背景色
        .Parent.Cells.Interior.ColorIndex = xlNone
        '設(shè)置選中區(qū)域所在行的背景色
        .EntireRow.Interior.Color = vbCyan
        '設(shè)置選中區(qū)域所在列的背景色
        .EntireColumn.Interior.Color = vbCyan
    End With
End Sub

　　返回Excel界面，在工作表SelectionChangeDemo中選中一個(gè)單元格區(qū)域C10：C14，顯示效果，第10行至第14行以及第3列單元格高亮顯示。

　?。矗罚场」ぷ鞑臼录?br>　　工作簿事件發(fā)生在特定的Workbook對(duì)象中。

　?。矗罚常薄pen事件

　　Open事件是Workbook對(duì)象最常用的事件之一，它發(fā)生于用戶(hù)打開(kāi)工作簿之時(shí)。

　　注意：在如下兩種情況下，打開(kāi)工作簿不會(huì)觸發(fā)Open事件。

　　　　?。保诎醋?lt;Shift>鍵的同時(shí)打開(kāi)工作簿。

　　　　?。玻诖蜷_(kāi)文件時(shí)的宏安全警告提示框里，選擇了“禁用宏”。

　　Open事件經(jīng)常被用來(lái)自動(dòng)設(shè)置用戶(hù)界面，這樣的好處在于，無(wú)論工作簿關(guān)閉時(shí)的狀態(tài)如何，再次打開(kāi)時(shí)都可以按照某個(gè)特定風(fēng)格呈現(xiàn)在用戶(hù)面前。

　　示例４７．３　自動(dòng)設(shè)置工作簿打開(kāi)時(shí)的界面風(fēng)格

　　步驟１．在Thisworkbook模塊中寫(xiě)入如下的Open事件代碼。

Private Sub Workbook_Open()
    'Excel窗口最大化
    Application.WindowState = xlMaximized
    With ActiveWindow
        '工作表窗口最大化
        .WindowState = xlMaximized
        '禁止顯示行標(biāo)和列標(biāo)
        .DisplayHeadings = False
    End With
    '激活Welcome工作表
    Sheets("Welcome").Select
End Sub

　　步驟２．返回Excel界面，選中Sheet1工作表。

　　步驟３．單擊Excel窗口右上角的向下還原按鈕，取消窗體最大化。

　　步驟４．單擊“文件”——“保存”。

　　步驟５．單擊“文件”——“退出”關(guān)閉工作簿。

　　步驟６．單擊“文件”——“打開(kāi)”，再次打開(kāi)剛才保存的工作簿。

　　步驟７．單擊安全警告提示框的“啟用宏”按鈕。

　　工作簿打開(kāi)后，Excel窗口是最大化的，Welcome工作表成為活動(dòng)工作表，而不是關(guān)閉工作簿時(shí)的Sheet1工作表。

　?。矗罚常病eforeClose事件

　　工作簿被關(guān)閉之前BeforeClose事件被激活。BeforeClose事件經(jīng)常和Open事件配合使用，在Open事件中修改的Excel設(shè)置和用戶(hù)界面，可以在BeforeClose事件中進(jìn)行恢復(fù)。

　　示例４７．４　關(guān)閉工作簿時(shí)自動(dòng)恢復(fù)Excel默認(rèn)界面風(fēng)格

　　在Thisworkbook模塊中寫(xiě)入如下的代碼：

Private Sub Workbook_Open()
    With Application
        '隱藏公式編輯欄
        .DisplayFormulaBar = False
        '設(shè)置鼠標(biāo)指針為沙漏型
        .Cursor = xlWait
    End With
End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
    With Application
        '顯示公式編輯欄
        .DisplayFormulaBar = True
        '恢復(fù)系統(tǒng)默認(rèn)鼠標(biāo)指針
        .Cursor = xlDefault
    End With
End Sub
　　保存并關(guān)閉工作簿，然后再次打開(kāi)工作簿，公式編輯欄已經(jīng)隱藏且鼠標(biāo)指針改為沙漏形。而在BeforeClose事件中，對(duì)相應(yīng)的設(shè)置進(jìn)行了恢復(fù)，所以工作簿關(guān)閉后，Excel將恢復(fù)默認(rèn)的系統(tǒng)設(shè)置。

　?。矗罚常场∪抗ぷ鞅硎褂孟嗤氖录a

　　工作簿事件有幾個(gè)名稱(chēng)是以“Sheet”開(kāi)頭的，這些事件的一個(gè)共同特點(diǎn)是，工作簿內(nèi)的任意工作表的行為都將觸發(fā)事件代碼的執(zhí)行。

　　如果希望所有的工作表都相應(yīng)相同的工作表事件代碼，有兩種實(shí)現(xiàn)方法：

　　１．在每個(gè)工作表代碼模塊中寫(xiě)入相同的事件代碼。

　　２．使用相應(yīng)的工作簿事件代碼。

　　毫無(wú)疑問(wèn)，第二種方法是最簡(jiǎn)潔的實(shí)現(xiàn)方法。

　　示例４７．５　高亮顯示任意工作表中選定區(qū)域所在的行和列

　　與示例４７．２相對(duì)應(yīng)，如果希望在工作簿中的任意工作表都擁有這種高亮顯示的效果，可以在Thisworkbook模塊中寫(xiě)入如下事件代碼：

Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
    With Target
        '清除工作表單元格的背景色
        .Parent.Cells.Interior.ColorIndex = xlNone
        '設(shè)置選中區(qū)域所在行的背景色
        .EntireRow.Interior.Color = vbCyan
        '設(shè)置選中區(qū)域所在列的背景色
        .EntireColumn.Interior.Color = vbCyan
    End With
End Sub
　　與示例４７．２相比，這種方法不必在每個(gè)工作表代碼模塊中寫(xiě)入相同的事件代碼，而且當(dāng)工作簿中新增工作表時(shí)，也無(wú)需為新建工作表添加Change事件代碼。

　?。矗罚础》菍?duì)象事件

　　Excel提供了兩種不與對(duì)象關(guān)聯(lián)的特殊事件，利用Application對(duì)象的相應(yīng)方法可以設(shè)置這些特殊事件。

　　４７．４．１　OnTime事件

　　OnTime事件指定一個(gè)過(guò)程在將來(lái)的特定時(shí)間運(yùn)行，此處的特定事件既可以是具體指定的某個(gè)時(shí)間點(diǎn)，也可以是指定的一段時(shí)間之后。

　　示例４７．６　文件保存提醒

　　步驟１．在工作簿中插入標(biāo)準(zhǔn)模塊，并在其中寫(xiě)入如下代碼。

　　'定義全局變量
Public iTime As Date
Sub SaveReminder()
    '判斷當(dāng)前工作簿是否被修改
    If ThisWorkbook.Saved = False Then
        '顯示消息框
        If MsgBox("為了防止數(shù)據(jù)丟失請(qǐng)保存文件" & _
               vbCrLf & "點(diǎn)擊<是>進(jìn)行保存", vbYesNo, "OnTimeDemo") = vbYes Then
               '如果用戶(hù)選擇<是>，則保存當(dāng)前工作簿
               ThisWorkbook.Save
        End If
    End If
    '記錄下次運(yùn)行的時(shí)間點(diǎn)
    iTime = Now + TimeValue("0:0:10")
    '設(shè)置10秒后再次運(yùn)行SaveReminder過(guò)程
    Application.OnTime iTime, "SaveReminder"
End Sub

　　步驟２．在Thisworkbook中寫(xiě)入如下代碼。

Private Sub Workbook_Open()
    '記錄下次運(yùn)行的時(shí)間點(diǎn)
    iTime = Now + TimeValue("0:0:10")
    '設(shè)置10秒后再次運(yùn)行SaveReminder過(guò)程
    Application.OnTime iTime, "SaveReminder"
End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
    '取消設(shè)置的自動(dòng)運(yùn)行
    Application.OnTime iTime, "SaveReminder", Schedule:=False
End Sub

　　步驟３．保存并關(guān)閉工作簿。

　　重新打開(kāi)工作簿，在１０秒鐘之后將看到工作簿保存提醒消息框。

　　Now函數(shù)返回當(dāng)前計(jì)算機(jī)系統(tǒng)設(shè)置的日期和時(shí)間：TimeValue("0:0:10")函數(shù)返回一個(gè)Date類(lèi)型數(shù)據(jù)，相當(dāng)于10秒；SaveReminder是標(biāo)準(zhǔn)模塊中在指定時(shí)間執(zhí)行的過(guò)程的名稱(chēng)。為了演示方便，示例中設(shè)定的較短的代碼執(zhí)行時(shí)間間隔。

　　首先在工作簿打開(kāi)時(shí)會(huì)觸發(fā)工作簿的Open事件，其中的OnTime設(shè)置10秒后運(yùn)行SaveReminder過(guò)程。

　　在SaveReminder過(guò)程中，判斷工作簿的Saved屬性的值，如果為False說(shuō)明工作簿已經(jīng)被修改，進(jìn)而提示用戶(hù)進(jìn)行保存，如果用戶(hù)單擊“是”按鈕，就保存當(dāng)前工作簿。在過(guò)程的最后，設(shè)置10秒后再次執(zhí)行SaveReminder過(guò)程代碼。

　　在工作簿的BeforClose事件中，利用Onkey方法的Schedule參數(shù)清除已經(jīng)設(shè)置的定時(shí)運(yùn)行過(guò)程，如果省略此代碼，即使工作簿已經(jīng)關(guān)閉，到達(dá)指定時(shí)間時(shí)，Excel將再次打開(kāi)工作簿運(yùn)行SaveReminder過(guò)程代碼。

　?。矗罚矗病nKey

　　使用OnKey方法可以設(shè)置按下特定的鍵或組合鍵時(shí)運(yùn)行指定的過(guò)程代碼。Excel會(huì)一直監(jiān)視著用戶(hù)的任何鍵盤(pán)操作，因此理論上可設(shè)置任何一個(gè)鍵或組合鍵來(lái)運(yùn)行指定的過(guò)程代碼。

　　注意：在工作表中輸入公式或在對(duì)話(huà)框中時(shí)，OnKey設(shè)置的組合鍵無(wú)效。

　　示例４７．７　為Excel設(shè)置自定義快捷鍵

　　步驟１．在工作簿中插入標(biāo)準(zhǔn)模塊，在模塊中寫(xiě)入如下代碼。

Sub OnKeyDemo()

       Application.OnKey"^a","CtrlA"

End Sub

Sub CtrlA()

       MsgBox "您按下了Ctrl+A組合鍵"

End Sub

　　步驟２．返回Excel界面，按<Ctrl+A>組合鍵，將出現(xiàn)消息框。

　　OnKey方法的參數(shù)"^a"中的"^"代表<Ctrl>鍵，關(guān)于其他功能鍵的表示方法請(qǐng)參考ＶＢＡ幫助。

　　默認(rèn)情況下，Excel中<Ctrl+A>組合鍵為選中工作表中的全部單元格。運(yùn)行OnKeyDemo過(guò)程之后，按<Ctrl+A>組合鍵將執(zhí)行CtrlA過(guò)程代碼顯示消息框。這也就是說(shuō)，OnKey方法設(shè)置的組合鍵與系統(tǒng)默認(rèn)的組合鍵相比有更高的優(yōu)先級(jí)。

　　使用如下的代碼可以恢復(fù)<Ctrl+A>組合鍵的默認(rèn)設(shè)置功能。

　　Application.OnKey"^a"

        在工作表中可以使用兩種控件：窗體控件和ActiveX控件，二者既有聯(lián)系又有明顯的區(qū)別。

　　４８．１　在工作表中插入控件

　　控件是在Excel與用戶(hù)交互時(shí)，用于輸入數(shù)據(jù)或操作數(shù)據(jù)的對(duì)象。在工作表中使用控件將為用戶(hù)提供更加友好的操作界面?？丶哂胸S富的屬性，并且可以被不同的事件激活以執(zhí)行相關(guān)代碼。

　　示例４８．１　在工作表中使用按鈕控件

　　下面介紹如何在工作表中插入按鈕控件。

　　步驟１．打開(kāi)一個(gè)新的工作簿。

　　步驟２．單擊菜單“視圖”——“工具欄”——“控件工具箱”；或者單擊Visual Basic工具欄上的“控件工具箱”按鈕，將顯示控件工具箱工具欄。

　　步驟３．單擊“命令按鈕”。

　　步驟４．移動(dòng)鼠標(biāo)至工作表的任意區(qū)域，光標(biāo)變?yōu)槭中巍?/div>