【原】DID中檢驗SUTVA問題, 附數(shù)據(jù)和代碼, 這幾個漸進性政策DID可視化做得真好

計量經(jīng)濟圈 2024-12-18 發(fā)布于浙江

展開全文

接著“很實用! 一張圖就把基準(zhǔn)回歸, 穩(wěn)健性檢驗, 異質(zhì)性分析, 安慰劑檢驗以及進一步拓展結(jié)果全囊括了”，這篇文章里作者做了DID中的SUTVA檢驗。

以下情況可能對“開放專利圖書館能夠促進創(chuàng)新”的觀點提出挑戰(zhàn)：圖書館的開放可能導(dǎo)致發(fā)明者在地理上的遷移，但對創(chuàng)新并未產(chǎn)生凈效應(yīng)。如果發(fā)明者因為圖書館的開放而遷移到專利圖書館所在地，那么所觀察到的變化可能只是專利活動在地理分布上的調(diào)整，而非創(chuàng)新活動的實際增加。在這種情況下，處理分配（treatment assignment）違反了穩(wěn)定單元處理值假設(shè)（SUTVA），因為專利圖書館的開放可能會削弱對照圖書館地區(qū)的創(chuàng)新能力。

為了探究這一可能性，重新進行了分析，假設(shè)那些最可能遷移至專利圖書館區(qū)域的發(fā)明者，來自地理位置上最接近的對照區(qū)域?；谶@一假設(shè)，對基準(zhǔn)分析進行了復(fù)現(xiàn)，這次排除了專利圖書館，轉(zhuǎn)而為每個被排除的專利圖書館最近的聯(lián)邦存儲圖書館分配了一個虛假的處理指示變量（就是造一個fake treatment）。在圖6的第8行展示了這些分析結(jié)果。結(jié)果顯示，相關(guān)系數(shù)略微為負(fù)，且在統(tǒng)計學(xué)上不顯著，同時與基準(zhǔn)系數(shù)的量級也不匹配，這表明與較遠(yuǎn)的對照圖書館相比，較近的對照圖書館并沒有顯示出明顯的趨勢差異。

分析一下，作者通過以下方式驗證了SUTVA（穩(wěn)定單元處理值假設(shè)）：

1.明確了潛在的SUTVA違反場景：假如專利圖書館的開放導(dǎo)致發(fā)明者從對照區(qū)域遷移到處理區(qū)域（即專利圖書館所在地），創(chuàng)新活動的地理分布會發(fā)生變化，而并非創(chuàng)新總量的真正增加。這種“干擾效應(yīng)”（interference）表明處理分配會間接影響未接受處理的對照單位，從而違反SUTVA的“無干擾”部分。

2.設(shè)計了檢驗SUTVA的偽處理實驗：為了檢驗這一假設(shè)，作者對基準(zhǔn)分析進行復(fù)現(xiàn)，但使用“偽處理”（fake treatment）的方法：剔除掉專利圖書館，并為每個被剔除掉的專利圖書館最近的聯(lián)邦存儲圖書館（原來的處理組）分配一個虛假處理變量。這一設(shè)計旨在模擬“如果存在發(fā)明者遷移干擾”的情況。

3.分析結(jié)果支持了SUTVA的有效性：偽處理分析顯示，與較遠(yuǎn)的對照圖書館相比，地理位置較近的聯(lián)邦存儲圖書館并未表現(xiàn)出顯著的創(chuàng)新趨勢差異。系數(shù)既不顯著也不匹配基準(zhǔn)分析的量級，這表明：沒有證據(jù)支持“專利圖書館開放導(dǎo)致發(fā)明者遷移”的假設(shè)；觀察到的創(chuàng)新增長并非僅僅由于地理分布的調(diào)整，而是實際創(chuàng)新活動的提升。這表明發(fā)明者的遷移并沒有導(dǎo)致對照圖書館區(qū)域的創(chuàng)新能力減弱，從而支持了SUTVA的“無干擾”假設(shè)。

提及SUTVA的post，參看1.CIC模型是對DID估計的推廣, 還能知道在不同分布處的處理效應(yīng)情況，2.近年來最全面和接地氣的“因果推斷統(tǒng)計學(xué)綜述”, 真后悔接觸這篇還是晚了點! 3.務(wù)必了解的綜述: 機器學(xué)習(xí)控制因果識別中的混淆變量大有可為！4.應(yīng)用計量經(jīng)濟學(xué)現(xiàn)狀: 因果推斷與政策評估最全綜述，5.誠實雙重差分法DID, 面板事件研究法和Bacon分解的經(jīng)典應(yīng)用文！6.在雙重差分模型中使用傾向得分估計政策變化效應(yīng)操作及注意事項! 附100篇相關(guān)文章! 7.最新: 時間序列因果推斷, 問題, 方法和模型最全綜述

*群友可前往社群下載完整數(shù)據(jù)和代碼.

**計量經(jīng)濟圈已調(diào)試，可以直接運行出結(jié)果。

* Test of SUTVA
use "D:/下載/129581-V1/Kit/data/main_work", clear
cap drop strata_id mean
drop if patent_lib==1
bys pat_ID: egen cf=min(pat_FDL_dist)
replace patent_lib=(pat_FDL_dist==cf)
replace treated = patent_lib

egen strata_id = group(pat_ID stateid)
bysort strata_id: egen mean = mean(treated)
drop if mean==0 | mean==1
keep if yearsopen10>=-5 & yearsopen10<=5
gen post = yearsopen10>=0
xi i.post*patent_lib, noomit
xtset identifier yearsopen10
cem pat_ID(#0) stateid(#0), treatment(treated)
drop if cem_matched==0
eststo r2: xtreg pat_pop_distance _IposXpaten_1 post patent_lib i.yearID2 [aweight=cem_weights], fe cluster(pat_ID)
sum pat_pop_distance
estadd scalar mean_scalar = r(mean)

其實，這里面“審稿人: 你DID模型中違反了個體處理穩(wěn)定性假設(shè)SUTVA, 盡快處理一下其中隱患！”提到的文獻就完全采用了類似的思路驗證SUTVA假設(shè)。

當(dāng)然，這篇文章在圖形展示方面確實做得非常出色，下面的漸進政策演進圖也繪制得非常清晰，既美觀又易于理解。

**計量經(jīng)濟圈已調(diào)試，可以直接運行出結(jié)果。
* Figure 2: Expansion in time
use "D:/下載/129581-V1/Kit/data/patent_lib", replace
keep city_library openingyear
gen one = 1
sort openingyear city_library
gen two = sum(one)
replace city_library = proper(city_library)
keep if openingyear>=1974 & openingyear<1998
twoway (scatter two openingyear if openingyear>=1975 & openingyear<=1980, msize(0.9) mlabel(city_library) color(gs4) msymbol(O) mlabsize(1.6))(scatter two openingyear if openingyear>1980 & openingyear<=1985, msize(0.9) mlabel(city_library) color(gs7) msymbol(D) mlabsize(1.6))(scatter two openingyear if openingyear>1985 & openingyear<=1990, msize(0.9) mlabel(city_library) color(gs10) msymbol(T) mlabsize(1.6))(scatter two openingyear if openingyear>1990 & openingyear!=., mlabel(city_library) msize(0.9) color(gs13) msymbol(S) mlabsize(1.6)), ysize(8) xscale(range(1975 2000)) xlabel(1975(5)2000) ytitle("Number of patent libraries in U.S.", size(3)) xtitle("Opening year", size(3)) legend(off)
graph export "D:/下載/129581-V1/Kit/results/Fig2.pdf", replace

畫地圖，其實Stata也不在話下，關(guān)鍵是作者的可視化做得真好。

**計量經(jīng)濟圈已調(diào)試，可以直接運行出結(jié)果，當(dāng)然中間需要下載一些命令，比如gtools。
* Figure 1: Expansion in space
use "D:/下載/129581-V1/Kit/data/patent_lib", replace
drop if openingyear==.
ren city_library lib_city
drop if openingyear>1997
gen old = openingyear<1975
drop if lng<-130

gen gradation=.
replace gradation=1 if openingyear>=1975 & openingyear<=1980
replace gradation=2 if openingyear>1980 & openingyear<=1985
replace gradation=3 if openingyear>1985 & openingyear<=1990
replace gradation=4 if openingyear>1990 & openingyear!=.

label define liblabel 0 "1870-1974" 1 "1975-1980"2 "1981-1985" 3 "1986-1990" 4 "after 1990"
label values gradation liblabel

save "D:/下載/129581-V1/Kit/data/oldPTDL", replace

cd "D:/下載/129581-V1/Kit/data/"
shp2dta using cb_2016_us_state_500k.shp, database("Newmap") coordinates("Newcoord") genid(id) replace

use Newmap.dta, clear

drop if NAME=="Alaska"
drop if NAME==" United States Virgin Islands"
drop if NAME=="Puerto Rico"
drop if NAME=="Hawaii"
drop if NAME=="Guam"
drop if id==33
drop if id==55
drop if id==56

spmap using Newcoord, id(id) point(data("oldPTDL.dta") select(drop if old==0) x(lng) y(lat ) sh (o) si(huge) fc(black) legenda(on) legtitle("Opened in") leglabel(1870-1974)) legend(size( normal) pos(5) region(fcolor(white)) symxsize(*0.5))
graph export "D:/下載/129581-V1/Kit/results/Fig1a.pdf", replace

spmap using Newcoord, id(id) point(data("oldPTDL.dta") select(drop if old==1) by(gradation) x(lng) y(lat ) sh (O D T S) si(large large large large) fc(gs4 gs7 gs10 gs13) legenda(on) legtitle("Opened in") ) legend(size( normal) pos(5) region(fcolor(white)) symxsize(*0.5))
graph export "D:/下載/129581-V1/Kit/results/Fig1b.pdf", replace

**計量經(jīng)濟圈已調(diào)試，可以直接運行出結(jié)果，當(dāng)然中間需要下載一些命令，比如gtools。
* Figure B-5

use "D:/下載/129581-V1/Kit/data/main_work", clear
keep pat_ID city_patent_library
duplicates drop
save "D:/下載/129581-V1/Kit/data/pat_ID_lib_city", replace

use "D:/下載/129581-V1/Kit/data/main_work", clear

gen b = .
gen se = .
gen number = .

egen yearID = group(yearsopen10)
gen post = yearsopen10>=0
xi i.post*patent_lib, noomit
xtset identifier yearsopen10
cem pat_ID(#0) stateid(#0) $matched, treatment(treated)
drop if cem_matched==0
eststo r0: reg pat_pop_distance _IposXpaten_1 post patent_lib i.yearID2 [aweight=cem_weights], cluster(pat_ID)

levelsof(pat_ID), local(pat)
local i = 1
foreach x in `pat' {
eststo r0: xtreg pat_pop_distance _IposXpaten_1 post patent_lib i.yearID2 [aweight=cem_weights] if pat_ID!=`x', fe cluster(pat_ID)
replace b = _b[_IposXpaten_1] in `i'
replace se = _se[_IposXpaten_1] in `i'
replace number = `x' in `i'
local i = `i'+1
}
sort b
keep b se number
ren number pat_ID
drop if pat_ID==.
joinby pat_ID using "data\pat_ID_lib_city"
replace city_patent_library = proper(city_patent_library)
gen upper = b+1.68*se
gen lower = b-1.68*se
set scheme lean1, perm
drop pat_ID
sort b
gen pat_ID=_n

labmask pat_ID, values(city_patent_library) // take over value label
twoway (scatter b pat_ID ,color(edkblue)) (rcap upper lower pat_ID,color(edkblue) ), yline(0) yscale(range(0 6)) ylabel(0(1)6) ytitle(Coefficient) legend(off) xtitle("") xlabel(1(1)45, valuelabel angle(90)) ytitle(Coefficient dropping one library)
graph export "D:/下載/129581-V1/Kit/results/FigB5.pdf", replace
erase "data\pat_ID_lib_city.dta"

*完整版數(shù)據(jù)和代碼可以直接前往社群下載。
關(guān)于多期DID或交疊DID: 1.DID相關(guān)前沿問題“政策交錯執(zhí)行+堆疊DID+事件研究”, 附完整slides，2.交錯(漸進)DID中, 用TWFE估計處理效應(yīng)的問題, 及Bacon分解識別估計偏誤，3.典范! 這篇AER在一圖表里用了所有DID最新進展方法, 審稿人直接服了！4.最新Sun和Abraham(2020)和TWFE估計多期或交錯DID并繪圖展示結(jié)果！詳細(xì)解讀code！5.多期DID或漸進DID或交疊DID, 最新Stata執(zhí)行命令整理如下供大家學(xué)習(xí)，6.多期DID前沿方法大討論, e.g., 進入-退出型DID, 異質(zhì)性和動態(tài)性處理效應(yīng)DID, 基期選擇問題等，7.交疊DID中平行趨勢檢驗, 事件研究圖繪制, 安慰劑檢驗的保姆級程序指南！8.欣慰! 營養(yǎng)午餐計劃終于登上TOP5! 交疊DID+異質(zhì)性穩(wěn)健DID！9.用事件研究法開展政策評估的過程, 手把手教學(xué)文章！10.從雙重差分法到事件研究法, 雙重差分濫用與需要注意的問題，11.系統(tǒng)梳理DID最新進展: 從多期DID的潛在問題到當(dāng)前主流解決方法和代碼! 12.標(biāo)準(zhǔn)DID中的平行趨勢檢驗,動態(tài)效應(yīng), 安慰劑檢驗, 預(yù)期效應(yīng)教程，13.DID從經(jīng)典到前沿方法的保姆級教程, 釋放最完整數(shù)據(jù)和代碼！