學習如果不去總結，知識總是別人的，只有不斷地去總結，消化，才會慢慢變成自己的！

數據查詢，辦公族基本天天用吧！我們之前出過一個小題，就是為了復習和鞏固，看到后，你腦中可有解法？

我想大部分同學都想到了VLOOKUP函數，其他的呢？還有嗎？

小編拙見，倒是有一些解法，不妨我們一起交流一下，以后再遇到這種問題，寫個10種解法，不過分吧！

友情提示：文末有同步視頻講解

▍解法01 - VLOOKUP函數

這是最常用也是最基本的，遇到這種數據查詢，一般都會想到使用VLOOKUP函數，關于VLOOKUP的用法，我寫的文章太多了，感興趣的，點擊公眾號頭像-放大鏡，輸入關鍵詞進行查找！我想關注我的朋友應該都會了吧！

=VLOOKUP($E2,$A$1:$C$14,COLUMN(B1),)

如果我們先依次得到兩列結果，也可以使用常量數組來代替COLUMN部分，數組公式！選擇F2:G2,Ctrl+Shift+Enter錄入，365版本回車即可，自動溢出

=VLOOKUP($E2,$A$1:$C$14,{2,3},)

の擴展：VLOOKUP函數基礎用法

▍解法02 - INDEX+MATCH

除了上面的解法，我們第二想到的就是INDEX+MATCH函數組合，他們一個找位置，一個根據位置提取內容，絕配~

=INDEX(B:B,MATCH($E2,$A:$A,))

の擴展：INDEX+MATCH我無敵，您隨意！

▍解法03 - LOOKUP函數

查詢類刨除他們兩組，第三個想到的就是LOOKUP函數了！LOOKUP函數固定套路用法，一般返回最后一個滿足條件的值！

=LOOKUP(1,0/($A$2:$A$14=$E2),B$2:B$14)

通用寫法： =LOOKUP(1,0/(條件區(qū)域=條件),結果區(qū)域)

の擴展：LOOKUP函數運行進制

▍解法04 - HLOOKUP函數

VLOOKUP使用頻率高，是因為數據部分一般都是按列，HLOOKUP函數他是從上往下查詢的，那么本案例中如何才能使用HLOOKUP來處理呢？答案是再加一個TRANSPOSE函數

=HLOOKUP($E2,TRANSPOSE($A$2:$C$14),COLUMN(B1),)

你問我TRANSPOSE函數這里怎么理解？看一下 選擇性粘貼-“轉置”。應該就能明白！

▍解法05 - XLOOKUP函數

XLOOKUP函數是真的香，有類似LOOKUP的查詢條件和結果列分列的書寫方便，還有IFERROR的容錯！

=XLOOKUP($E2,$A$2:$A$14,B2:B14)

什么你問我有沒有關于XLOOKUP的講解文章，有，必學有！

の擴展：XLOOKUP函數詳解，精通不過分！

▍解法06 - FILTER函數

FILTER函數在數據篩選過濾方面，真的無敵，我愿意成為“最方便、最直觀”！

FILTER(返回列,條件區(qū)域列=條件） 返回滿足條件的結果，如果是多個，返回數組！

=FILTER(B$2:B$14,$A$2:$A$14=$E$2)

▍解法07- REDUCE函數

REDUCE函數，之前我們剛分享過，他其實是一個循環(huán)遍歷函數，這里使用并不是最優(yōu)，但是也算是一種思路，所以我們分享出來！

=REDUCE("",A2:A14,LAMBDA(x,y,IF(y=$E$2,OFFSET(y,,1,1,2),x)))

如果你看不明白，不妨看看下面這篇文章！

の擴展：REDUCE函數入門詳解

▍解法08- DGET函數

從大家提交上來的答案來看，沒有一個同學想到，真的是冷門了嗎？

“D”開頭的函數，Excel中有幾個，他們統稱為“數據庫函數”！

DGET函數(區(qū)域,返回列,條件）

=DGET($A$1:$C$14,F1,$E$1:$E$2)

由于這個函數，我們前兩天剛寫過專題講解，大家可以參考一下！

の擴展：DGET函數入門詳解+案例

以上就是全部解法嗎？并不是，還有很多，只是有一些單純?yōu)榱恕皽悺?，實?zhàn)中使用較少，我們就未在這里公布！不過掌握上面的幾種解法，那么再遇到這種問題，都將不再是問題！

最后來一張合照（不要我提醒你，保存?zhèn)洳榱税桑?img src="">）

對了，我們還有配套的講解視頻！更多視頻教程，也可以關注我們的視頻號！