^{<noscript id="ijm09"></noscript>}

【新提醒】凹底淘金（讀書筆記）

普明666 2017-06-09

展開全文

倍量:=VOL>REF(V,1)*2.10 AND C>REF(C,1);
小倍陽:=VOL>=REF(V,1)*1.85 AND VOL<=REF(V,1)*2.10 AND C>REF(C,1);
低量:=VOL=LLV(VOL,20) AND V>0;
高量:=VOL=HHV(VOL,15) AND V>0;
平量:=V>REF(V,1)*0.98 AND V<REF(V,1)*1.02;
倍縮:=VOL<=REF(V,1)*1/2;
縮三一:=VOL<=REF(V,1)*2/3;
縮三二:=VOL<=REF(V,1)*1/3;
梯量:=COUNT(V>REF(V,1),2)=2 AND COUNT(C>REF(C,1),3)=3;
縮量漲:=COUNT(C>REF(C,1),2)=2 AND COUNT(V<REF(V,1),2)=2;
百日地量:=VOL<=LLV(V,100);
T4變異:=COUNT(REF(V,1)>REF(V,2),2)=2 AND COUNT(C>=REF(C,1),4)=4;
T4:=FILTER(T4變異,3);

陽線:=C>=REF(C,1);
陰線:=C<REF(C,1);

三日前收陽:=REF(C,3)>=REF(C,4) AND REF(C,3)>=REF(O,3);
三日前高量:=REF(V,3)>HHV(V,10);

三日最低不破頂:=LLV(C,3)>=REF(C,3);
三日均價不破頂:=MA(C,3)>=REF(C,3);
三日不破頂:=三日最低不破頂 OR 三日均價不破頂;

三日最低不破底:=LLV(C,3)>=REF(O,3);
三日均價不破底:=MA(C,3)>=REF(O,3);
三日不破底:=三日最低不破底 OR 三日均價不破底;

三日前倍量:=REF(V,3)>=(REF(V,4)*1.8);
三日前陽勝:=REF(C,3)>REF(C,4) AND REF(V,3)>REF(V,4) AND REF(C,3)>REF(O,4);
收陽次數(shù):=COUNT(C>REF(C,1),3)>=1;

三日量不過頂:=HHV(V,3)<=REF(V,3);
三日均量不過頂:=MA(V,3)<=REF(V,3);
價升大于量升:=MA(C,3)/REF(C,3) >= (MA(V,3)/REF(V,3) * 1.2);

價量:=三日量不過頂 OR 三日均量不過頂 OR 價升大于量升;

倍量黃金柱:=三日前倍量 AND 三日不破頂 AND 三日前收陽 AND 價量 AND 收陽次數(shù);
高量黃金柱:=三日前高量 AND 三日不破頂 AND 三日前收陽 AND 價量 AND 收陽次數(shù);
陽勝黃金柱:=三日前陽勝 AND 三日不破頂 AND 三日前收陽 AND 價量 AND 收陽次數(shù);
倍量將軍柱:=三日前倍量 AND 三日不破底 AND 三日前收陽 AND 價量 AND 收陽次數(shù);
高量將軍柱:=三日前高量 AND 三日不破底 AND 三日前收陽 AND 價量 AND 收陽次數(shù);
陽勝將軍柱:=三日前陽勝 AND 三日不破底 AND 三日前收陽 AND 價量 AND 收陽次數(shù);

黃金柱:=倍量黃金柱 OR 高量黃金柱 OR 陽勝黃金柱;
將軍柱:=倍量將軍柱 OR 高量將軍柱 OR 陽勝將軍柱;

HT:=5*V;
WT:=0.3;

STICKLINE(陽線,0,HT,1,0),COLOR0000AA;
STICKLINE(陰線,0,HT,1,0),COLOR00AA00;
STICKLINE(倍量,0,HT,WT,0),COLORYELLOW;
STICKLINE(低量,0,HT,WT,0),COLORBLACK;
STICKLINE(平量,0,HT,WT,0),COLORWHITE;
STICKLINE(梯量,0,HT,WT,0),COLORGRAY;
STICKLINE(縮量漲,0,HT,WT,0),COLORBLUE;
STICKLINE(縮三一,0,HT,WT,0),COLORLIRED;
STICKLINE(倍縮,0,HT,WT,0),COLORCYAN;
STICKLINE(縮三二,0,HT,WT,0),COLORLIGRAY;
STICKLINE(小倍陽,0,HT,WT,0),COLORYELLOW;
STICKLINE(將軍柱,0,HT,WT,0),COLORLIMAGENTA;

DRAWTEXT(百日地量,V*10, '地'),COLORYELLOW;
DRAWTEXT(高量,HT,'高'),COLORYELLOW;

DRAWTEXT(T4,V*3.5, 'T4'),COLORYELLOW;
DRAWTEXT(黃金柱,V*3,'<-'),COLORYELLOW;
DRAWTEXT(黃金柱,V*1.5,'金'),COLORYELLOW;
DRAWTEXT(小倍陽,V*4, '倍'),COLORYELLOW;