處理Selection對象和Range對象——Word VBA中重要的兩個對象

Word 開發(fā)人員參考
Selection 對象
代表窗口或窗格中的當前所選內容。所選內容代表文檔中選定（或突出顯示）的區(qū)域，如果文檔中沒有選定任何內容，則代表插入點。每個文檔窗格只能有一個 Selection 對象，并且在整個應用程序中只能有一個活動的 Selection 對象。
說明

可以使用 Selection 屬性返回 Selection 對象。如果 Selection 屬性未使用對象限定符，則 Microsoft Office Word 返回活動文檔窗口的活動窗格中的所選內容。以下示例從活動文檔中復制當前所選內容。

Selection.Copy

以下示例刪除 Documents 集合中第三個文檔的所選內容。訪問該文檔的當前所選內容時，該文檔無需處于活動狀態(tài)。

Documents(3).ActiveWindow.Selection.Cut

以下示例復制活動文檔第一個窗格中的所選內容，并將其粘貼到第二個窗格中。

ActiveDocument.ActiveWindow.Panes(1).Selection.Copy
ActiveDocument.ActiveWindow.Panes(2).Selection.Paste

Text 屬性是 Selection 對象的默認屬性。使用此屬性可設置或返回當前所選內容中的文本。以下示例將當前所選內容中的文本賦給變量 strTemp。如果最后一個字符是段落標記，則刪除該字符。

Dim strTemp as String

strTemp = Selection.Text
If Right(strTemp, 1) = vbCr Then _
    strTemp = Left(strTemp, Len(strTemp) - 1)

Selection 對象有多種方法和屬性，可用于折疊、擴展或以其他方式更改當前所選內容。以下示例將插入點移至文檔末尾并選擇最后三行。

Selection.EndOf Unit:=wdStory, Extend:=wdMove
Selection.HomeKey Unit:=wdLine, Extend:=wdExtend
Selection.MoveUp Unit:=wdLine, Count:=2, Extend:=wdExtend

Selection 對象有多種方法和屬性，可用于編輯文檔中的所選文字。以下示例選擇活動文檔中的第一句，并用新段落替換該句。

Options.ReplaceSelection = True
ActiveDocument.Sentences(1).Select
Selection.TypeText "Material below is confidential."
Selection.TypeParagraph

以下示例刪除 Documents 集合中第一個文檔的最后一段，并將其粘貼到第二個文檔的開頭。

With Documents(1)
    .Paragraphs.Last.Range.Select
    .ActiveWindow.Selection.Cut
End With

With Documents(2).ActiveWindow.Selection
    .StartOf Unit:=wdStory, Extend:=wdMove
    .Paste
End With

Selection 對象有多種方法和屬性，可用于更改當前所選內容的格式。以下示例將當前所選內容的字體從 Times New Roman 更改為 Tahoma。

If Selection.Font.Name = "Times New Roman" Then _
    Selection.Font.Name = "Tahoma"

可以使用 Flags、Information 和 Type 等屬性返回有關當前所選內容的信息。您可以在某個過程中使用以下示例來確定活動文檔中是否選擇了內容，如果未選擇，則跳過該過程的其余部分。

If Selection.Type = wdSelectionIP Then
    MsgBox Prompt:="You have not selected any text! Exiting procedure..."
    Exit Sub
End If

即使將所選內容折疊到插入點，相應內容也不一定為空。例如，Text 屬性仍將字符返回到插入點右側，此字符也會出現(xiàn)在 Selection 對象的 Characters 集合中。但是，從折疊的所選內容調用 Cut 或 Copy 等方法將引起錯誤。

用戶可以選擇文檔中不代表連續(xù)文本的區(qū)域（例如，在使用 Alt 鍵和鼠標時）。由于這種所選內容的行為不可預知，因此，您可能希望在代碼中包含一個步驟，先檢查所選內容的 Type 屬性，然后再對它執(zhí)行任意操作 (Selection.Type = wdSelectionBlock)。同樣，包含表格單元格的所選內容也會導致不可預知的行為。Information 屬性將指示所選內容是否在某個表中 (Selection.Information(wdWithinTable) = True)。以下示例確定所選內容是否正常（例如，它不是表中的行或列，也不是垂直文本塊，等等），您可以先用該示例對當前所選內容進行測試，然后再對它執(zhí)行任意操作。

If Selection.Type <> wdSelectionNormal Then
    MsgBox Prompt:="Not a valid selection! Exiting procedure..."
    Exit Sub
End If

由于 Range 對象與 Selection 對象的許多方法和屬性都相同，因此，如果沒有必要對當前所選內容進行實際更改，最好使用 Range 對象來處理文檔。有關 Selection 對象和 Range 對象的詳細信息，請參閱處理 Selection 對象和處理 Range 對象。

2006 Microsoft Corporation。保留所有權利。

=================================================================================
Word 開發(fā)人員參考
處理 Selection 對象

用 Microsoft Office Word 處理文檔時，通常先選定文字，然后對所選內容執(zhí)行操作，例如設置文字格式或鍵入文字。在 Microsoft Visual Basic 中，通常不需要在修改文字前先選定文字，而是創(chuàng)建一個引用文檔中特定區(qū)域的 Range 對象。有關定義 Range 對象的信息，請參閱處理 Range 對象。但是，如果希望代碼響應或更改所選內容，則可使用 Selection 對象。

如果尚未選定文本，可使用 Select 方法選擇與特定對象關聯(lián)的文本并創(chuàng)建一個 Selection 對象。例如，下面的指令選定活動文檔中的第一個單詞。

Sub SelectFirstWord()
    ActiveDocument.Words(1).Select
End Sub

有關詳細信息，請參閱在文檔中選定文字。

如果已經(jīng)選定文本，可使用 Selection 屬性返回一個 Selection 對象，該對象表示文檔中當前選定的內容。每個文檔只能有一個 Selection 對象，該對象始終訪問當前選定內容。下面的示例更改當前選定內容中段落的格式。

Sub FormatSelection()
    Selection.Paragraphs.LeftIndent = InchesToPoints(0.5)
End Sub

本示例在當前選定內容后插入單詞“Hello”。

Sub InsertTextAfterSelection()
    Selection.InsertAfter Text:="Hello "
End Sub

本示例對選定文本應用加粗格式。

Sub BoldSelectedText()
    Selection.Font.Bold = True
End Sub

宏錄制器經(jīng)常會創(chuàng)建使用 Selection 對象的宏。下面的示例是使用宏錄制器創(chuàng)建的。該宏選擇活動文檔中的前兩個單詞并對其應用加粗格式。

Sub Macro()
    Selection.HomeKey Unit:=wdStory
    Selection.MoveRight Unit:=wdWord, Count:=2, Extend:=wdExtend
    Selection.Font.Bold = wdToggle
End Sub

下面的示例完成相同的任務，但不選擇文本，也不使用 Selection 對象。

Sub WorkingWithRanges()
    ActiveDocument.Range(Start:=0, _
        End:=ActiveDocument.Words(2).End).Bold = True
End Sub

2006 Microsoft Corporation。保留所有權利。

=================================================================================

Word 開發(fā)人員參考
Range 對象
代表文檔中的一個連續(xù)區(qū)域。每個 Range 對象由一個起始字符位置和一個終止字符位置定義。
說明

與書簽在文檔中的使用方法類似，Range 對象在 Visual Basic 過程中用來標識文檔的特定部分。但與書簽不同的是，Range 對象只在定義該對象的過程運行時才存在。Range 對象獨立于所選內容。也就是說，您可以定義和處理一個范圍而無需更改所選內容。還可以在文檔中定義多個范圍，但每個窗格中只能有一個所選內容。

使用 Range 方法可返回一個 Range 對象，該對象由指定的起始和終止字符位置定義。以下示例返回一個代表活動文檔中前 10 個字符的 Range 對象。

Set myRange = ActiveDocument.Range(Start:=0, End:=10)

使用 Range 屬性可返回一個 Range 對象，該對象由另一對象的起點和終點定義。Range 屬性可應用于許多對象（例如，Paragraph、Bookmark 和 Cell）。以下示例返回一個代表活動文檔中第一段的 Range 對象。

Set aRange = ActiveDocument.Paragraphs(1).Range

以下示例返回一個代表活動文檔中第二至第四段的 Range 對象。

Set aRange = ActiveDocument.Range( _
    Start:=ActiveDocument.Paragraphs(2).Range.Start, _
    End:=ActiveDocument.Paragraphs(4).Range.End)

有關處理 Range 對象的詳細信息，請參閱處理 Range 對象。

2006 Microsoft Corporation。保留所有權利。

=================================================================================
Word 開發(fā)人員參考
處理 Range 對象
全部顯示
全部隱藏

使用 Microsoft Visual Basic 完成的一種常見任務是在文檔中指定一個區(qū)域，然后對該區(qū)域進行某些操作，如插入文字或應用格式。例如，您可能需要編寫一個宏，用于在文檔的某部分中查找一個單詞或詞組。該文檔部分可以用 Range 對象表示。標識 Range 對象后，就可以應用 Range 對象的方法和屬性來修改該區(qū)域的內容。

Range 對象引用文檔中的某一連續(xù)區(qū)域。每個 Range 對象都是通過開始和結束字符位置來定義的。與在文檔中使用書簽的方法類似，在 Visual Basic 過程中使用 Range 對象可以標識文檔中的特定部分。Range 對象可以小至一個插入點，或大至整個文檔。但是與書簽不同，Range 對象只在定義它的過程運行時才存在。

Start、End 和 StoryType 屬性唯一地標識一個 Range 對象。Start 和 End 屬性返回或設置 Range 對象的開始和結束字符的位置。文檔開始處的字符位置為 0，第一個字符后的位置為 1，依此類推。StoryType 屬性的 WdStoryType 常量可以代表 11 種不同的文章類型。

  注釋
Range 對象與所選內容無關。也就是說，可以定義和修改某區(qū)域而不改變當前的所選內容。也可定義文檔中的多個區(qū)域，而每個文檔窗格中只有一處所選內容。

使用 Range 方法
使用 Document 對象的 Range 方法可創(chuàng)建一個 Range 對象，該對象位于主文字部分 （文章：單個文本框或一串相鏈接文本框中包含的文字。）中并具有給定的起點和終點。下面的示例創(chuàng)建一個 Range 對象，該對象從第一個字符的開始位置開始并延伸到第十個字符。

Sub SetNewRange()
    Dim rngDoc As Range
    Set rngDoc = ActiveDocument.Range(Start:=0, End:=10)
End Sub

將屬性或方法應用于 Range 對象時，可以看到已經(jīng)創(chuàng)建了 Range 對象。下面的示例對活動文檔的前 10 個字符應用加粗格式。

Sub SetBoldRange()
    Dim rngDoc As Range
    Set rngDoc = ActiveDocument.Range(Start:=0, End:=10)
    rngDoc.Bold = True
End Sub

如果需要多次引用一個 Range 對象，可使用 Set 語句設置一個其值為該 Range 對象的變量。但是，如果僅需要對 Range 對象執(zhí)行一次操作，則不必將該對象存儲在變量中。只使用一個標識區(qū)域并更改 Bold 屬性的指令，也能得到相同的結果。

Sub BoldRange()
    ActiveDocument.Range(Start:=0, End:=10).Bold = True
End Sub

類似于書簽，一個區(qū)域可以跨越一組字符或標記文檔中的某個位置。下列示例中的 Range 對象的開始和結束位置相同。該區(qū)域不包含任何文字。下列示例在活動文檔的開頭插入文字。

Sub InsertTextBeforeRange()
    Dim rngDoc As Range
    Set rngDoc = ActiveDocument.Range(Start:=0, End:=0)
    rngDoc.InsertBefore "Hello "
End Sub

可以使用上述字符位置編號，或通過將 Start 和 End 屬性用于 Selection、Bookmark 或 Range 等對象，來定義區(qū)域的開始和結束位置。下面的示例創(chuàng)建一個 Range 對象，該對象從第二段開頭開始，至第三段末尾結束。

Sub NewRange()
    Dim doc As Document
    Dim rngDoc As Range

    Set doc = ActiveDocument
    Set rngDoc = doc.Range(Start:=doc.Paragraphs(2).Range.Start, _
        End:=doc.Paragraphs(3).Range.End)
End Sub

有關其他信息和示例，請參閱 Range 方法。

使用 Range 屬性
有多個對象具有 Range 屬性，如 Paragraph、Bookmark 和 Cell。該屬性用于返回 Range 對象。下面的示例返回一個 Range 對象，該對象引用活動文檔中的第一段。

Sub SetParagraphRange()
    Dim rngParagraph As Range
    Set rngParagraph = ActiveDocument.Paragraphs(1).Range
End Sub

得到 Range 對象后，可使用它的任何屬性或方法來修改該 Range 對象。下列示例選定活動文檔中的第二個段落并將所選內容居中。

Sub FormatRange()
    ActiveDocument.Paragraphs(2).Range.Select
    Selection.ParagraphFormat.Alignment = wdAlignParagraphCenter
End Sub

若要對同一個 Range 對象應用多種屬性或方法，可使用 With…End With 結構。下列示例設置活動文檔中第一段的文字格式。

Sub FormatFirstParagraph()
    Dim rngParagraph As Range
    Set rngParagraph = ActiveDocument.Paragraphs(1).Range
    With rngParagraph
        .Bold = True
        .ParagraphFormat.Alignment = wdAlignParagraphCenter
        With .Font
            .Name = "Stencil"
            .Size = 15
        End With
    End With
End Sub

有關其他信息和示例，請參閱 Range 屬性主題。

重新定義 Range 對象
使用 SetRange 方法可重新定義現(xiàn)有的 Range 對象。下面的示例將一個區(qū)域定義為當前的所選內容。然后應用 SetRange 方法以重新定義該區(qū)域，使之包含當前所選內容和接下來的 10 個字符。

Sub ExpandRange()
    Dim rngParagraph As Range
    Set rngParagraph = Selection.Range
    rngParagraph.SetRange Start:=rngParagraph.Start, _
        End:=rngParagraph.End + 10
End Sub

有關其他信息和示例，請參閱 Document 的 Range 方法。

  注釋
調試宏時，可以使用 Select 方法確保 Range 對象引用正確的文本區(qū)域。例如，下面的示例選擇一個 Range 對象，該對象引用活動文檔中的第二段和第三段，然后設置所選內容的字體格式。

Sub SelectRange()
    Dim rngParagraph As Range

    Set rngParagraph = ActiveDocument.Paragraphs(2).Range

    rngParagraph.SetRange Start:=rngParagraph.Start, _
        End:=ActiveDocument.Paragraphs(3).Range.End
    rngParagraph.Select

    Selection.Font.Italic = True
End Sub

2006 Microsoft Corporation。保留所有權利。

=========================================================================
Word 開發(fā)人員參考
WdStoryType 枚舉
指定選定內容或項目的部分類型。
名稱 值 描述
wdCommentsStory 4 批注部分。
wdEndnoteContinuationNoticeStory 17 尾注延續(xù)標記部分。
wdEndnoteContinuationSeparatorStory 16 尾注延續(xù)分隔符部分。
wdEndnoteSeparatorStory 15 尾注分隔符部分。
wdEndnotesStory 3 尾注部分。
wdEvenPagesFooterStory 8 偶數(shù)頁頁腳部分。
wdEvenPagesHeaderStory 6 偶數(shù)頁頁眉部分。
wdFirstPageFooterStory 11 首頁頁腳部分。
wdFirstPageHeaderStory 10 首頁頁眉部分。
wdFootnoteContinuationNoticeStory 14 腳注延續(xù)標記部分。
wdFootnoteContinuationSeparatorStory 13 腳注延續(xù)分隔符部分。
wdFootnoteSeparatorStory 12 腳注分隔符部分。
wdFootnotesStory 2 腳注部分。
wdMainTextStory 1 正文部分。
wdPrimaryFooterStory 9 主頁腳部分。
wdPrimaryHeaderStory 7 主頁眉部分。
wdTextFrameStory 5 文本框架部分。

=========================================================================
Word 開發(fā)人員參考
WdUnits 枚舉
指定要使用的度量單位。
名稱 值 描述
wdCell 12 單元格。
wdCharacter 1 字符。
wdCharacterFormatting 13 字符格式。
wdColumn 9 列。
wdItem 16 所選項。
wdLine 5 一個線段。
wdParagraph 4 段落。
wdParagraphFormatting 14 段落格式。
wdRow 10 行。
wdScreen 7 屏幕尺寸。
wdSection 8 一節(jié)。
wdSentence 3 句子。
wdStory 6 部分。
wdTable 15 一個表格。
wdWindow 11 窗口。
wdWord 2 字。

2006 Microsoft Corporation。保留所有權利。
=========================================================================
Word 開發(fā)人員參考
WdSelectionType 枚舉
指定選擇類型。
名稱 值 描述
wdNoSelection 0 沒有選定內容。
wdSelectionBlock 6 列方式選定。
wdSelectionColumn 4 列選擇。
wdSelectionFrame 3 框架選擇。
wdSelectionInlineShape 7 內嵌形狀選擇。
wdSelectionIP 1 內嵌段落選擇。
wdSelectionNormal 2 標準的或用戶定義的選擇容。
wdSelectionRow 5 行選擇。
wdSelectionShape 8 形狀選擇。

2006 Microsoft Corporation。保留所有權利。

=========================================================================
Word 開發(fā)人員參考
Selection.Information 屬性
返回有關指定的選定內容的信息。Variant 類型，只讀。
語法

表達式.Information(Type)

表達式   必選。一個代表 Selection 對象的變量。

參數(shù)

名稱 必選/可選 數(shù)據(jù)類型 描述
Type 必選 WdInformation 信息類型。

示例

本示例顯示當前頁碼和活動文檔的總頁數(shù)。

Visual Basic for Applications
MsgBox "The selection is on page " & _
    Selection.Information(wdActiveEndPageNumber) & " of page " _
    & Selection.Information(wdNumberOfPagesInDocument)

如果選定內容位于一個表格中，則本示例選定該表格。

Visual Basic for Applications
If Selection.Information(wdWithInTable) Then _
    Selection.Tables(1).Select

本示例顯示一條消息，表明當前的節(jié)號。

Visual Basic for Applications
Selection.Collapse Direction:=wdCollapseStart
MsgBox "The insertion point is in section " & _
    Selection.Information(wdActiveEndSectionNumber)

2006 Microsoft Corporation。保留所有權利。

======================================================================
Word 開發(fā)人員參考
WdInformation 枚舉
指定返回的涉及指定所選內容或區(qū)域的信息的類型。
名稱 值 描述
wdActiveEndAdjustedPageNumber 1 返回頁碼，在該頁中包含指定的所選內容或區(qū)域的活動結尾。如果設置一個起始頁碼或進行其他手動調整，則返回經(jīng)調整的頁碼（與  wdActiveEndPageNumber 不同）。
wdActiveEndPageNumber 3 返回頁碼，在該頁中包含指定的所選內容或區(qū)域的活動結尾。從文檔開頭計數(shù)。忽略任何對頁碼的手動調整（與  wdActiveEndAdjustedPageNumber 不同）。
wdActiveEndSectionNumber 2 返回節(jié)號，在該節(jié)中包含了指定的所選內容或區(qū)域的活動結尾。
wdAtEndOfRowMarker 31 如果指定的所選內容或區(qū)域位于表格的行結尾標記處，則該參數(shù)返回 True。
wdCapsLock 21 如果 Caps Lock 有效，則該參數(shù)返回 True。
wdEndOfRangeColumnNumber 17 返回表格列號，在該表格列中包含指定的所選內容或區(qū)域的結尾。
wdEndOfRangeRowNumber 14 返回表格行號，在該表格行中包含指定的所選內容或區(qū)域的結尾。
wdFirstCharacterColumnNumber 9 返回指定的所選內容或區(qū)域中第一個字符的位置。如果所選內容或區(qū)域是折疊的，則返回緊靠所選內容或區(qū)域右側的字符編號（該編號與狀態(tài)欄中“列”后面的字符列數(shù)相同）。
wdFirstCharacterLineNumber 10 返回指定的所選內容或區(qū)域中第一個字符的位置。如果所選內容或區(qū)域是折疊的，則返回緊靠所選內容或區(qū)域右側的字符編號（該編號與狀態(tài)欄中“行”后面的字符行數(shù)相同）。
wdFrameIsSelected 11 如果所選內容或區(qū)域是一個完整的圖文框或文本框，則該參數(shù)返回 True。
wdHeaderFooterType 33 返回一個值，該值指示包含了指定所選內容或區(qū)域的頁眉或頁腳的類型。有關其他信息，請參閱“注解”部分中的表。
wdHorizontalPositionRelativeToPage 5 返回指定的所選內容或區(qū)域的水平位置。該位置是所選內容或區(qū)域的左邊緣與頁面的左邊緣之間的距離，以磅為單位（1 磅 = 20 緹，72 磅 = 1 英寸）。如果所選內容或區(qū)域未顯示在屏幕上，則該參數(shù)返回 -1。
wdHorizontalPositionRelativeToTextBoundary 7 返回指定所選內容或區(qū)域相對于周圍最近的正文邊界左邊緣的水平位置，以磅為單位（1 磅 = 20 緹，72 磅 = 1 英寸）。如果所選內容或區(qū)域未顯示在屏幕上，則該參數(shù)返回 -1。
wdInClipboard 38 有關該常量的信息，請參閱包含在 Microsoft Office Macintosh Edition 中的語言參考幫助。
wdInCommentPane 26 如果指定的所選內容或區(qū)域位于批注窗格，則該參數(shù)返回 True。
wdInEndnote 36 如果指定的所選內容或區(qū)域位于頁面視圖的尾注區(qū)內，或者位于普通視圖的尾注窗格中，則該參數(shù)返回 True。
wdInFootnote 35 如果指定的所選內容或區(qū)域位于頁面視圖的腳注區(qū)內，或者位于普通視圖的腳注窗格中，則該參數(shù)返回 True。
wdInFootnoteEndnotePane 25 如果指定的所選內容或區(qū)域位于普通視圖的腳注或尾注窗格中，或頁面視圖的腳注或尾注區(qū)內，則該參數(shù)返回 True。有關詳細信息，請參閱前面關于  wdInFootnote 和  wdInEndnote 的說明。
wdInHeaderFooter 28 如果指定的所選內容或區(qū)域位于頁眉或頁腳窗格中，或者位于頁面視圖的頁眉或頁腳中，則該參數(shù)返回 True。 
wdInMasterDocument 34 如果所選內容或區(qū)域位于主控文檔（即至少包含一個子文檔的文檔）中，則該參數(shù)返回 True。
wdInWordMail 37 如果指定的所選內容或區(qū)域位于頁眉或頁腳窗格中，或者位于頁面視圖的頁眉或頁腳中，則該參數(shù)返回 True。
wdMaximumNumberOfColumns 18 返回所選內容或區(qū)域中任何行的最大表格列數(shù)。
wdMaximumNumberOfRows 15 返回指定的所選內容或區(qū)域中表格的最大行數(shù)。
wdNumberOfPagesInDocument 4 返回與所選內容或區(qū)域相關聯(lián)的文檔的頁數(shù)。
wdNumLock 22 如果 Num Lock 有效，則該參數(shù)返回 True。 
wdOverType 23 如果啟用改寫模式，則該參數(shù)返回 True?？墒褂?Overtype 屬性改變改寫模式的狀態(tài)。
wdReferenceOfType 32 返回一個值，該值表明所選內容相對于腳注、尾注或批注引用的位置，如“注解”部分中的表所示。
wdRevisionMarking 24 如果打開修訂功能，則該參數(shù)返回 True。
wdSelectionMode 20 返回一個值，該值表明當前的選定模式，如下表所示。
wdStartOfRangeColumnNumber 16 返回表格列號，在該表格列中包含所選內容或區(qū)域的起點。
wdStartOfRangeRowNumber 13 返回表格行號，在該表格行中包含所選內容或區(qū)域的起點。
wdVerticalPositionRelativeToPage 6 返回所選內容或區(qū)域的垂直位置，即所選內容的上邊緣與頁面的上邊緣之間的距離，以磅為單位（1 磅 = 20 緹，72 磅 = 1 英寸）。如果所選內容未顯示在文檔窗口中，則該參數(shù)返回 -1。
wdVerticalPositionRelativeToTextBoundary 8 返回所選內容或區(qū)域相對于周圍最近的正文邊界的上邊緣的垂直位置，以磅為單位（1 磅 = 20 緹，72 磅 = 1 英寸）。該參數(shù)可用于在圖文框或表格中確定插入點位置。如果所選內容未顯示在屏幕中，則該參數(shù)返回 -1。
wdWithInTable 12 如果所選內容位于表格中，則該參數(shù)返回 True。 
wdZoomPercentage 19 返回由  Percentage 屬性設置的當前的放大百分比。

說明

下表列出了 wdHeaderFooterType 的可能值。

值 頁眉或頁腳的類型
-1 無（所選內容或區(qū)域不在頁眉或頁腳中）
0（零） 偶數(shù)頁頁眉
1 奇數(shù)頁頁眉（或在不區(qū)分奇數(shù)和偶數(shù)頁時的頁眉）
2 偶數(shù)頁頁腳
3 奇數(shù)頁頁腳（或在不區(qū)分奇數(shù)和偶數(shù)頁時的頁腳）
4 第一個頁眉
5 第一個頁腳

下表列出了 wdReferenceOfType 的可能值。

值 說明
-1 所選內容或區(qū)域包含但不限于腳注、尾注或批注引用。
0（零） 所選內容或區(qū)域不在腳注、尾注或批注引用之前。
1 所選內容或區(qū)域位于腳注引用之前。
2 所選內容或區(qū)域位于尾注引用之前。
3 所選內容或區(qū)域位于批注引用之前。

下表列出了 wdSelectionMode 的可能值。

值 選定模式
0（零） 常規(guī)選定模式
1 擴展選定模式(“擴展”出現(xiàn)在狀態(tài)欄上)
2 列選擇模式（“列”出現(xiàn)在狀態(tài)欄上)

2006 Microsoft Corporation。保留所有權利。

======================================================================
Word 開發(fā)人員參考
選定文檔中的文本

使用 Select 方法可以選擇文檔中的對象。Select 方法可用于多個對象，例如 Bookmark、Field、Range 和 Table。下面的示例選定活動文檔中的第一個表格。

Sub SelectTable()
    ActiveDocument.Tables(1).Select
End Sub

下面的示例選定活動文檔中的第一個域。

Sub SelectField()
    ActiveDocument.Fields(1).Select
End Sub

下面的示例選定活動文檔中的前四個段落。Range 方法用于創(chuàng)建一個引用前四個段落的 Range 對象，然后將 Select 方法應用于 Range 對象。

Sub SelectRange()
    Dim rngParagraphs As Range
    Set rngParagraphs = ActiveDocument.Range( _
        Start:=ActiveDocument.Paragraphs(1).Range.Start, _
        End:=ActiveDocument.Paragraphs(4).Range.End)
    rngParagraphs.Select
End Sub

有關詳細信息，請參閱處理 Selection 對象。

2006 Microsoft Corporation。保留所有權利。