函數(shù)：LLVBARS(X,N)
描述：上一低點位置
類別：引用
參數(shù)： 無
返回： 無
說明：求N周期內(nèi)X最低值到當前周期數(shù)，N=0表示從第一個有效值開始統(tǒng)計
示例：LLVBARS(HIGH,10)求得10日最低點到當前的周期數(shù)
當前N天之內(nèi)的最高點和最低點就一目了然了：
A:=BACKSET(ISLASTPERIOD,HHVBARS(H,N)+1);
B:=COUNT(A,N)=1;{取得前N個周期內(nèi)的最高點位置}
REF(H,BARSLAST(B));
DRAWICON(B,H,1),ALIGN2;
A2:=BACKSET(ISLASTPERIOD,LLVBARS(L,N)+1);
B2:=COUNT(A2,N)=1;{取得前N個周期內(nèi)的最低點位置}
REF(L,BARSLAST(B2));
DRAWICON(B2,L,2),ALIGN1;{主圖疊加。N：30,1,9999}
這個公式求前期高低點，在600036等次新股上試調(diào)整參數(shù)就露馬腳了，并不完善。問題出在HHVBARS起算點等原因上。
下面這個公式可以說是完美解決方案：
HH:HHV(H,N),LINETHICK2;
LL:LLV(L,N),LINETHICK2;{主圖疊加，參數(shù)N：30，1,9999}
當N個周期之內(nèi)，有兩個最高價，即有等高的情況出現(xiàn)，HHVBARS會返回哪個最高價到當前的周期數(shù)呢？
用副圖公式觀察一下，N取10：
HHVBARS(H,N);
我們可以得出結(jié)論，返回的是前一個最高價到當前的周期數(shù)。同樣，當在N個周期之內(nèi)，有兩個等低的最低價出現(xiàn)時，LLVBARS會返回前一個最低價到當前的周期數(shù)。
0079--窄幅整理
(HHV(C,20)-LLV(C,20)/C<0.08;
0080--N天前到M天前之間的最高價
REF(HHV(H,20),40);
0081--某時間段最高價
HH:=IF(YEAR=1998 AND MONTH>=8 AND MONTH<=12,H,0);
HHV(HH,0);{此例求1998年8月1日到1998年12月31日間的最高價}
0082--二十日內(nèi)是否有過漲停
TT:=C/REF(C,1)>1.095;
COUNT(TT,20)>0;
0083--放量創(chuàng)新高
AA:=MA(V,5);
BB:=REF(AA,2);
CC:=HHV(C,30);
AA/BB>2 AND C=CC;
0084--突破長期平臺整理
V1:=MA(V,5);
V2:=V/REF(V1,1);
PZ1:=MA(C,150);
PZ2:=HHV(H,150);
PZ3:=LLV(L,150);
PZ4:=(PZ2-PZ1)/PZ1;
PZ5:=(PZ1-PZ3)/PZ1;
PZ:=REF(PZ4,1)<0.15 AND REF(PZ5,1)<0.15;
TP1:=HHV(H,150);
TP:=H=TP1;
V2>=2 AND PZ AND TP
0085--尾盤大單拉升或打壓
AA:=TIME>=145500;
BB:=SUM(V,0)/240;//當天均量
CC:=SUM(V,10)/10;//10分鐘內(nèi)的成交均量
DD:=REF(C,10);
AA AND CC/BB>3 AND C/DD>1.02;
0086--MACD柱狀體變寬語法
Moving Average Convergence/Divergence , MACD , 移動平均收斂/發(fā)散指針
Param(LONG , 26 ,20 100)
Param(SHORT , 12 , 5 ,40)
Param(M , 9 , 2 , 60)
DIFF:EMA( CLOSE , SHORT ) - EMA( CLOSE , LONG) ,LINETHICK0,COLOR99FFFF;
DEA:EMA( DIFF , M ) ,LINETHICK0,COLORFF9966;
MACD: 2 * ( DIFF - DEA ) ,LINETHICK0,COLOR9966FF;
STICKLINE(MACD>0,0,MACD,6,1) ,COLOR9966FF;
STICKLINE(MACD<=0,0,MACD,6,1) ,COLORCCFF66;
PARTLINE(C>0,DIFF) ,COLOR99FFFF;
PARTLINE(C>0,DEA) ,COLORFF9966;
英譯：
DIFF=Difference = 差異=差離值
DEA=Difference Exponential Average= 差異的指數(shù)平滑移動平均=差離值平均值
MACD=Moving Average Convergence/Divergence = 移動平均收斂/發(fā)散
利用快速和慢速兩條指數(shù)平滑移動平均線，計算兩者之間的差離值DIFF
再利用差離值DIFF，來計算差離值平均值DEA
本公式MACD柱狀，即可明顯體現(xiàn)出了DIFF與DEA兩者的收斂交會與發(fā)散分離的情況，
用以研判買進或賣出的時機
0087--傅立葉變換
用法：FFT(X , N)
傅立葉變換，對數(shù)列X進行傅立葉變換，或變換處理后反變換
示例：
當N=0時，對數(shù)列X進行傅立葉變換；
當N=1時，對數(shù)列X進行傅立葉變換后，再反變換回來，與原X一致；
當N>1時，對數(shù)列X進行傅立葉變換后，舍去周期小于N的成分后再反變換回來；
傅立葉變換是最常用的積分變換。原理和對數(shù)變換等差不多，廣泛應(yīng)用于工程技術(shù)領(lǐng)域。可傅立葉變換的算法，涉及高等數(shù)學的微積分知識，非三言兩語說得清楚。
傅立葉變換的應(yīng)用方面：把FFT(CLOSE,30)，在主圖中上移、下移之后，可以構(gòu)成非常光滑的信道。
AA:FFT(CLOSE,30);
XX:AA*1.05;
YY:AA*0.95;
0088--周期切換
函數(shù)： DATATYPE
別名： DATAPERIOD,、數(shù)據(jù)周期類型
用法：
DATATYPE
回傳值竹范圍為0-11
分別表示分筆成交、1分鐘、5分鐘、15分鐘、30分鐘、60分鐘、
日、周、月、年、多日、多分鐘
范例：切換到日線時跑最高價、切換到周線時跑最低價?？紤]到什么周期秀什么線的問題
XH:=IF( DATATYPE=6 , 1 , 0 ) ;
XL:=IF( DATATYPE=7 , 1 , 0 ) ;
AA:=MA(C , XH)/MA(C , XH) ;
BB:=MA(C , XL)/MA(C , XL) ;
HH:=HIGH ;
LL:=LOW ;
日線最高價:AA*HH , COLORGREEN ;
周線最低價:BB*LL , COLORYELLOW ;
范例：切換到指數(shù)類STKTYPE=0 跑10均線，切換到個股類STKTYPE=5 跑30均線。
XA:=IF( STKTYPE=0 , 1 , 0 ) ;
XB:=IF( STKTYPE=5 , 1 , 0 ) ;
AA:=IF( XA=1 , MA(C,10) , 0 ) ;
BB:=IF( XB=1 , MA(C,30) , 0 ) ;
指針線:AA+BB ;
范例：標記當天分時K線的當天K線序號。過了午夜12點，就又要等早盤開盤后序號數(shù)字才會出現(xiàn)
XA:=CURRENTDATE=DATE ;
XB:=REF(XA , 1)<>XA ;
XC:HHVBARS(XB , 0) + XA ;
應(yīng)用：13均線當天當下最后數(shù)值向后延申，畫平臺線。
XA:=CURRENTDATE=DATE ;
XB:=REF(XA , 1)<>XA ;
XC:=HHVBARS(XB , 0) + XA ;
XD:=MA(C,13);
XE:=REFX(XD , 300);
XF:IF(XC>=0 , XE , 0) ,LINETHICK0,COLOR99FFFF;
PARTLINE(XC>=1 , XF) ,COLOR99FFFF;
0089--公歷農(nóng)歷
范例：公歷日期
YY:=YEAR*10000;
MM:=MONTH*100;
DD:=DAY ;
公歷日期:YY+MM+DD ,LINETHICK0;
范例：農(nóng)歷日期
LY:=LYEAR*10000;
LM:=LMONTH*100;
LD:=LDAY;
農(nóng)歷日期:LY+LM+LD ,LINETHICK0;
范例：兩個日期相差天數(shù)→橫坐標切換→自然日坐標和交易日坐標效果不一樣
兩日期相差天數(shù)A: DATEDIFF(1020929,1021003),LINETHICK0;
兩日期相差天數(shù)B: DATEDIFF(LSOLARTERMDATE(1), DATE),LINETHICK0;
范例：9點:30分:59秒以前的分時K線，指定一個值=1給它，其它為=0
N:=30;
XA:IF((HOUR=8) OR (HOUR=9 AND MINUTE>=0 AND MINUTE<=N) , 1 , 0 ) , STICK ;
上面和下面的語法，其意義相同：
范例：9點:30分:59秒 以前的分時K線 ，指定一個值=1給它，其它為=0
N:=30;
XA:(HOUR=8) OR (HOUR=9 AND MINUTE>=0 AND MINUTE<=N) , STICK ;
范例：開盤第一根分時K線，指定一個值=1給它，其它為0
XA:REF(DATE,1)<>DATE , STICK;
范例：每天的分時K線，指定它的當天K線序號給它
XA:=REF(DATE,1)<>DATE , STICK;
XB:BARSLAST(XA=1) + 1 ,STICK;
0090--添加自己的特色指針子選單
方法如下：
在C:\CHIEFOX\SYSTEM\下建立SPECINDI.INI文件，例如其內(nèi)容如下：
[特色指針]
追漲體系=0,RSI;0,KDJ;
條件選股=0,BIAS;3,K110;2,BIAS
打開記事本，輸入上面文字后，存盤時記得擴展名由TXT→改為INI
批注：
各指針間以分號相隔?！ ?br> 指針名稱逗號前的數(shù)字表示公式類型：
0：技術(shù)指針，1：條件選股 2：交易系統(tǒng) 3：五彩K線
再啟動看看：
功能選單：特色→特色指針，將會出現(xiàn)子選單"追漲體系"、"條件選股"。
0091--5日均線轉(zhuǎn)折價
將公式建立在：技術(shù)指針( ○主圖 ●主圖疊加 )
公式名稱：KKK27
參數(shù)PARAM( N，5，2，300 )
MMA:MA( CLOSE , N ) ;
RMA:=REF( MMA , 1 ) ;
MMB:=MA( CLOSE , N-1 ) ;
RMB:=REF( MMB , 1 ) ;
均線今轉(zhuǎn)折:( RMA * N ) - ( RMB * ( N-1) ) , LINETHICK5 , POINTDOT ;
均線明轉(zhuǎn)折:( MMA * N ) - ( MMB * ( N-1 ) ) , LINETHICK5 , POINTDOT ;
說明：
1. REF( X , N ) 函數(shù)：將線圖 X 向右平移 N 周期。
2. X , SHIFT N 函數(shù)：將線圖 X 向右平移 N 周期。(這兩者之間的差別驗證看看就知道了)
3.
收盤站在轉(zhuǎn)折價之上→均線將走正斜率。
收盤等于轉(zhuǎn)折價→均線將走零斜率。
收盤落入轉(zhuǎn)折價之下→均線將走負斜率。
5日均線
使CROSS(CLOSE , MA( CLOSE , 5 ) )成立轉(zhuǎn)折價
將公式建立在：技術(shù)指針( ○主圖 ●主圖疊加 )
公式名稱：KKK40
參數(shù)PARAM( N，5，2，300 )
MMA:MA (CLOSE , N ) ;
TT:=MA( C , N-1 ) ;
DD:=REF( TT , 1 ) ;
PARTLINE( CLOSE>0, DD ) , CROSSDOT , COLOR6A9BFF ;
PARTLINE( CLOSE>0 , TT ) , CROSSDOT , COLORFFAB60 ;
EXPLAINEX( CLOSE>0 , '均線今轉(zhuǎn)折 ' , DD , 2 , 0 ) , COLOR6A9BFF;
EXPLAINEX( CLOSE>0 , '均線明轉(zhuǎn)折 ' , TT , 2 , 0 ) , COLORFFAB60 ;
說明：
BB=MA( C , 4 )
RB=REF( BB , 1 )
令
今轉(zhuǎn)折價為 CC
CC=(4*RB) / 5 + (CC) / 5
5*CC=4*RB + CC ;
4*CC=4*RB
CC=RB
同理可證：
令
明轉(zhuǎn)折價為MM
MM=BB
5日均線
使CROSS(CLOSE , MA( CLOSE , 5 ) )成立 轉(zhuǎn)折價(含周均線)
將公式建立在：技術(shù)指針( ○主圖 ●主圖疊加 ) 先建立即將被引用的表達式
公式名稱：KKK45
參數(shù)PARAM( N，5，2，300 )
MMA:MA (CLOSE , N ) ;
TT:MA( C , N-1 ) ;
DD:REF( TT , 1 ) ;
將公式建立在：技術(shù)指針( ○主圖 ●主圖疊加 )
公式名稱：KKK45.1
參數(shù)PARAM( N，5，2，300 )
MMA:"KKK45.MMA"(N) ;
MMW:"KKK45.MMA#WEEK"(N) ;
TT:="KKK45.TT"(N) ;
DD:="KKK45.DD"(N) ;
WT:="KKK45.TT#WEEK"(N) ;
WD:="KKK45.DD#WEEK"(N) ;
PARTLINE( CLOSE>0, DD ) , CROSSDOT , COLOR6A9BFF ;
PARTLINE( CLOSE>0 , TT ) , CROSSDOT , COLORFFAB60 ;
PARTLINE( CLOSE>0, WD ) , CROSSDOT , COLOR88FB66 ;
PARTLINE( CLOSE>0, WT ) , CROSSDOT , COLORB982FD;
EXPLAINEX( CLOSE>0 , '均線今轉(zhuǎn)折 ' , DD , 2 , 0 ) , COLOR6A9BFF;
EXPLAINEX( CLOSE>0 , '均線明轉(zhuǎn)折 ' , TT , 2 , 0 ) , COLORFFAB60 ;
EXPLAINEX( CLOSE>0 , '\N均線今周轉(zhuǎn)折 ' , WD , 2 , 0 ) , COLOR88FB66 ;
EXPLAINEX( CLOSE>0 , '均線下周轉(zhuǎn)折 ' , WT , 2 , 0 ) , COLORB982FD ;
0092--平均真實波幅 ATR BANDS
METASTOCK FORMULAS
ATR BANDS
STDHA := MOV(C,20,E)+2*ATR(20) ;
STDLA := MOV(C,20,E)-2*ATR(20) ;
STDHA;
STDLA
真實波幅TRUE RANGE是以下三者最大的一項：
(A). 當天最高價至最低價的幅度。
(B). 當天最高價至昨天收盤價的幅度。
(C). 當天最低價與昨天收盤價的幅度。
公式名稱：KKK43
將公式建立在：技術(shù)指針 ( ○主圖 ●主圖疊加 )
RC:=REF( C , 1 ) , LINETHICK0 ;
XA:=IF( RC>H , RC , 0 ) ;
XB:=IF( H>=RC AND RC>L , H , 0 ) ;
XC:=IF( RC<=L , H , 0 ) ;
XD:=XA+XB+XC ;
YA:=IF( RC>H , L , 0 ) ;
YB:=IF( H>=RC AND RC>L , L , 0 ) ;
YC:=IF( RC<=L , RC , 0 ) ;
YD:=YA+YB+YC ;
ATR:=SMA( (XD - YD) , 20 , 1 ) ;
STDHA:EMA( C , 20 ) + 2*ATR ;
STDLA:EMA( C , 20 ) - 2*ATR ;
0093--SYSPARAM(1)函數(shù)的說明
SYSPARAM(1)函數(shù)：主要應(yīng)用在，線圖會隨十字游標的移動而變化。
公式名稱：KKK12
將公式建立在：技術(shù)指針 ( ○主圖 ●主圖疊加 )
SS:=SYSPARAM( 1 ) ;
DD:=SUM( 1 , 0 ) ;
CC:CLOSE * 1.07 , LINETHICK0 , COLORYELLOW ;
PARTLINE( SS>=DD , CC ) , COLORYELLOW ;
注：
DD:SUM( 1 , 0 ) ;
SS:SYSPARAM( 1 ) ;
上面兩者，顯然有明顯的不同之處。
1. DD是一條變量型時間數(shù)列→代表K線的序號下標。
2. SS是一組包含N 條的常數(shù)型時間數(shù)列( N=這支股票的K線總數(shù))。
0094--真實波幅AND平均真實波幅。
真實波幅TRUE RANGE是以下三者最大的一項：
(A). 當天最高價至最低價的幅度。
(B). 當天最高價至昨天收盤價的幅度。
(C). 當天最低價與昨天收盤價的幅度。
將公式建立在：技術(shù)指針( ○主圖 ●主圖疊加 )
公式名稱：KKK36
收盤價:CLOSE , POINTDOT , LINETHICK6 ;
RC:REF( C , 1 ) , LINETHICK0 ;
XA:=IF( RC>H , RC , 0 ) ;
XB:=IF( H>=RC AND RC>L , H , 0 ) ;
XC:=IF( RC<=L , H , 0 ) ;
XD:XA+XB+XC ;
YA:=IF( RC>H , L , 0 ) ;
YB:=IF( H>=RC AND RC>L , L , 0 ) ;
YC:=IF( RC<=L , RC , 0 ) ;
YD:YA+YB+YC ;
ATR:SMA( ( XD - YD ) , 14 , 1 ) , LINETHICK0 ;
真實波幅TRUE RANGE是以下三者最大的一項：
(A). 當天最高價至最低價的幅度。
(B). 當天最高價至昨天收盤價的幅度。
(C). 當天最低價與昨天收盤價的幅度。
將公式建立在：技術(shù)指針( ○主圖 ●主圖疊加 )
公式名稱：KKK36
收盤價:CLOSE , POINTDOT , LINETHICK6 ;
RC:REF( C , 1 ) , LINETHICK0 ;
XA:=IF( RC>=H , RC , 0 ) ;
XB:=IF( RC< H , H , 0 ) ;
XD:XA+XB ;
YA:=IF( RC>L , L , 0 ) ;
YB:=IF( RC<=L , RC , 0 ) ;
YD:YA+YB ;
TR:SMA( ABS( XD - YD ) , 14 , 1 ) , LINETHICK0 ;
0095--條件成立當日低點向后劃水平線直到水平線跌破。
條件A，例如CROSS( K , 80 )，
在 條件A 成立的當天取當根K棒的“最低價X”作為“水平直線”的起點，然后一直隨著未來的K棒自動向右延伸，“直到”有一天的“收盤價小于”當初條件成立時的那個“最低價X”時，這一條“水平直線”便到了終點。
將下面公式建立在：技術(shù)指針( ○主圖 ●主圖疊加 )
公式名稱：KKK29
參數(shù)PARAM( N，9，1，100 )
參數(shù)PARAM( M1，3，2，40 )
參數(shù)PARAM( M2，3，2，40 )
RSV:=( CLOSE-LLV(LOW,N) ) / ( HHV(HIGH,N)-LLV(LOW,N) ) * 100 ;
K:=SMA( RSV , M1 , 1 ) , COLORRED ;
D:=SMA( K , M2 , 1 ) , COLORYELLOW ;
AA:=CROSS( K , 80 ) ;
BB:=BARSLAST( AA=1 ) ;
DD:=REF( LOW , BB ) ;
EE:=CROSS( DD , CLOSE ) ;
FF:=SUM( EE , BB ) ;
GG:=( REF( FF , 1 )=0 AND FF=1 ) ;
HH:=( REF(DD,1)=DD ) ;
PARTLINE( HH=1 , DD ) ;
DRAWLINE( AA=1 , DD , GG=1 , DD , 0 ) , COLORC080FF ;
0096--分析周期切換→均線參數(shù)自動切換(1)
日線 MA5，MA10，MA20，MA30，MA72
周線 MA6，MA12，MA24，MA72
其它周期參數(shù)，自行類推。
將公式建立在：技術(shù)指針( ○主圖 ●主圖疊加 )
公式名稱：KKK25.2 (完成品)
XA:=IF( DATAPERIOD=6 , 5 , 0 ) ;
XB:=IF( DATAPERIOD=6 , 10 , 0 ) ;
XC:=IF( DATAPERIOD=6 , 20 , 0 ) ;
XD:=IF( DATAPERIOD=6 , 30 , 0 ) ;
XE:=IF( DATAPERIOD=6 , 72 , 0 ) ;
TT:=SUM( 1 , 0 ) ;
A1:=ISLASTBAR ;
A2:=BACKSET( A1=1 , TT-4 ) ;
A3:=BARSLAST( A2=1 ) ;
X1:=A3 + 1 ;
MA5:MA( C , XA ) * X1 ;
B1:=ISLASTBAR ;
B2:=BACKSET( B1=1 , TT-9 ) ;
B3:=BARSLAST( B2=1 ) ;
X2:=B3 + 1 ;
MA10:MA( C , XB ) * X2 ;
C1:=ISLASTBAR ;
C2:=BACKSET( C1=1 , TT-19 ) ;
C3:=BARSLAST( C2=1 ) ;
X3:=C3 + 1 ;
MA20:MA( C , XC ) * X3 ;
D1:=ISLASTBAR ;
D2:=BACKSET( D1=1 , TT-29 ) ;
D3:=BARSLAST( D2=1 ) ;
X4:=D3 + 1 ;
MA30:MA( C , XD ) * X4 ;
E1:=ISLASTBAR ;
E2:=BACKSET( E1=1 , TT-71 ) ;
E3:=BARSLAST( E2=1 ) ;
X5:=E3 + 1 ;
MA72:MA( C , XE ) * X5 ;
YA:=IF( DATAPERIOD=7 , 6 , 0 ) ;
YB:=IF( DATAPERIOD=7 , 12 , 0 ) ;
YC:=IF( DATAPERIOD=7 , 24 , 0 ) ;
YD:=IF( DATAPERIOD=7 , 72 , 0 ) ;
A11:=ISLASTBAR ;
A22:=BACKSET( A11=1 , TT-5 ) ;
A33:=BARSLAST( A22=1 ) ;
Y1:=A33 + 1 ;
MB6:MA( C , YA ) * Y1 ;
B11:=ISLASTBAR ;
B22:=BACKSET( B11=1 , TT-11 ) ;
B33:=BARSLAST( B22=1 ) ;
Y2:=B33 + 1 ;
MB12:MA( C , YB ) * Y2 ;
C11:=ISLASTBAR ;
C22:=BACKSET( C11=1 , TT-23 ) ;
C33:=BARSLAST( C22=1 ) ;
Y3:=C33 + 1 ;
MB24:MA( C , YC ) * Y3 ;
D11:=ISLASTBAR ;
D22:=BACKSET( D11=1 , TT-71 ) ;
D33:=BARSLAST( D22=1 ) ;
Y4:=D33 + 1 ;
MB72:MA( C , YD ) * Y4 ;
說明：
只顯示后面15(預(yù)設(shè))天的線圖(不使用VBS)：
將下列公式建立在：技術(shù)指針 ( ●主圖 ○主圖疊加 )
公式名稱：KKK17.1
參數(shù)PARAM( N、15、1、300 )
AA:=ISLASTBAR ;
BB:=BACKSET( AA=1 , N ) ;
Y:=BARSLAST( BB=1 ) ;
X:=Y + 1 ;
OO:OPEN * X ;
MM:MA( CLOSE , 5 ) * X ;
將公式建立在：技術(shù)指針( ○主圖 ●主圖疊加 )
公式名稱：KKK25 (半成品)
XA:=IF( DATAPERIOD=6 , 5 , 0 ) ;
XB:=IF( DATAPERIOD=6 , 10 , 0 ) ;
XC:=IF( DATAPERIOD=6 , 20 , 0 ) ;
XD:=IF( DATAPERIOD=6 , 30 , 0 ) ;
XE:=IF( DATAPERIOD=6 , 72 , 0 ) ;
MA5:MA( C , XA ) ;
MA10:MA( C , XB ) ;
MA20:MA( C , XC ) ;
MA30:MA( C , XD ) ;
MA72:MA( C , XE ) ;
YA:=IF( DATAPERIOD=7 , 6 , 0 ) ;
YB:=IF( DATAPERIOD=7 , 12 , 0 ) ;
YC:=IF( DATAPERIOD=7 , 24 , 0 ) ;
YD:=IF( DATAPERIOD=7 , 72 , 0 ) ;
MB6:MA( C , YA ) ;
MB12:MA( C , YB ) ;
MB24:MA( C , YC ) ;
MB72:MA( C , YD ) ;
注：
當前分析周期類型: DATAPERIOD ;
DATAPERIOD 函數(shù) → 回傳值的范圍介于 0 -- 10 之間 。分別代表 當前分析周期類型。
0 → 分筆成交
1 → 1 分鐘線
2 → 5 分鐘線
3 → 15分鐘線
4 → 30分鐘線
5 → 60分鐘線
6 → 日線
7 → 周線
8 → 月線
9 → 年線
10 → 多日線
小技巧：
在圖形分析窗口可用 鍵盤精靈 切換分析周期。
0097--分析周期切換→均線參數(shù)自動切換(2)
日線 MA5，MA10，MA20，MA30，MA72
周線 MA6，MA12，MA24，MA72
其它周期參數(shù)，自行類推。
將公式建立在：技術(shù)指針( ○主圖 ●主圖疊加 )
公式名稱：KKK25.5 (完成品)
XA:=( DATAPERIOD=6 )*5 ;
XB:=( DATAPERIOD=6 )*10 ;
XC:=( DATAPERIOD=6 )*20 ;
XD:=( DATAPERIOD=6 )*30 ;
XE:=( DATAPERIOD=6 )*72 ; {常數(shù)型 時間數(shù)列 ，將之代入 MA函數(shù) 會正確}
MA5:MA( C , XA ) ;
MA10:MA( C , XB ) ;
MA20:MA( C , XC ) ;
MA30:MA( C , XD ) ;
MA72:MA( C , XE ) ;
YA:=( DATAPERIOD=7 )*6 ;
YB:=( DATAPERIOD=7 )*12 ;
YC:=( DATAPERIOD=7 )*24 ;
YD:=( DATAPERIOD=7 )*72 ;
MB6:MA( C , YA ) ;
MB12:MA( C , YB ) ;
MB24:MA( C , YC ) ;
MB72:MA( C , YD ) ;
將公式建立在：技術(shù)指針( ○主圖 ●主圖疊加 )
公式名稱：KKK25 (半成品)
XA:=IF( DATAPERIOD=6 , 5 , 0 ) ;
XB:=IF( DATAPERIOD=6 , 10 , 0 ) ;
XC:=IF( DATAPERIOD=6 , 20 , 0 ) ;
XD:=IF( DATAPERIOD=6 , 30 , 0 ) ;
XE:=IF( DATAPERIOD=6 , 72 , 0 ) ;
{有點變量型時間數(shù)列的味道，因為IF函數(shù)在做怪，將之代入MA函數(shù)會失真}
MA5:MA( C , XA ) ;
MA10:MA( C , XB ) ;
MA20:MA( C , XC ) ;
MA30:MA( C , XD ) ;
MA72:MA( C , XE ) ;
YA:=IF( DATAPERIOD=7 , 6 , 0 ) ;
YB:=IF( DATAPERIOD=7 , 12 , 0 ) ;
YC:=IF( DATAPERIOD=7 , 24 , 0 ) ;
YD:=IF( DATAPERIOD=7 , 72 , 0 ) ;
MB6:MA( C , YA ) ;
MB12:MA( C , YB ) ;
MB24:MA( C , YC ) ;
MB72:MA( C , YD ) ;
注：
當前分析周期類型: DATAPERIOD ;
PP:( DATAPERIOD=6 ) ; { PP為常數(shù)型時間數(shù)列 }
0098--調(diào)用某某公式內(nèi)的時間數(shù)列線
公式名稱：BB
SS:=HIGH< REF( HIGH , 1 ) ; {不輸出的表達式，如果被引用還是會變成不輸出的表達式}
RR:REF( HIGH , 6 ) ; {輸出的表達式，如果被引用還是會變成輸出的表達式}
公式名稱： BBQ
TT:"BB.SS" ; {不輸出的表達式}
PP:"BB.RR" ; {輸出的表達式}
1. 調(diào)用公式BB內(nèi)的SS時間數(shù)列。調(diào)用公式BB內(nèi)的RR時間數(shù)列。
2. 當SS線內(nèi)存有預(yù)設(shè)參數(shù)時，例如有兩個參數(shù)，可視情況寫成PP:"BB.SS"(N,M) 。
3. 例如 K:="KD.K"( 10 , 4 , 0 ) ; → 調(diào)用公式 KD 內(nèi)的 K 時間數(shù)列 。
3. 例如 D:="KD.D"( 10 , 4 , 4 ) ; → 調(diào)用公式 KD 內(nèi)的 D 時間數(shù)列 。
4. 例如 K:="KD.K" ; → 使用公式 KD 預(yù)設(shè)的參數(shù) ，( 9 , 3 , 0 )。
4. 例如 K:="KD.D" ; → 使用公式 KD 預(yù)設(shè)的參數(shù) ，( 9 , 3 , 3 )。
公式名稱：KD
參數(shù)PARAM( N，9，1，100 )
參數(shù)PARAM( M1，3，2，40 )
參數(shù)PARAM( M2，3，2，40 )
RSV:=( CLOSE-LLV( LOW , N ) ) / ( HHV( HIGH , N )-LLV( LOW , N ) )*100 ;
K:SMA( RSV , M1 , 1 ) ; {K數(shù)列內(nèi)包含了兩個參數(shù)因子：N，M1}
D:SMA( K , M2 , 1 ) ; {D數(shù)列內(nèi)包含了三個參數(shù)因子：N，M1，M2}
(1) 多頭: 周線9K>9D時選出日線9K>9D的股票
(2) 空頭: 周線9K<9D時選出日線9K<9D的股票
公式A. 先建立即將被引用的表達式
建立一個專門被用來引用(QUOTE)的公式區(qū)。
將公式建立在：技術(shù)指針( ●主圖 ○主圖疊加 )
公式名稱：KDD
參數(shù)PARAM( N，9，1，100 )
參數(shù)PARAM( M1，3，2，40 )
參數(shù)PARAM( M2，3，2，40 )
RSV:=( CLOSE-LLV(LOW,N) ) / ( HHV(HIGH,N)-LLV(LOW,N) ) * 100 ;
K:SMA( RSV , M1 , 1 ) , COLORRED ;
D:SMA( K , M2 , 1 ) , COLORYELLOW ;
公式B.
將公式建立在：技術(shù)指針( ●主圖 ○主圖疊加 )
公式名稱：KDD1
K:"KDD.K" ;
D:"KDD.D" ;
WK:"KDD.K#WEEK" ;
WD:"KDD.D#WEEK" ;
公式B.
將公式建立在：條件選股
公式名稱：KDD2(多頭)
K:="KDD.K" ;
D:="KDD.D" ;
WK:="KDD.K#WEEK" ;
WD:="KDD.D#WEEK" ;
K>D AND WK>WD
公式C.
將公式建立在：條件選股
公式名稱：KDD3(空頭)
K:="KDD.K" ;
D:="KDD.D" ;
WK:="KDD.K#WEEK" ;
WD:="KDD.D#WEEK" ;
K< D AND WK< WD
0099--三角函數(shù)AND角度線
∠A 的對邊長度 = A
∠B 的對邊長度 = B
∠C 的對邊長度 = C → 斜邊
ù=3.14159
1 度 = ( ù / 180 ) 弧度
∠B = 22.5 度 = ( 1 / 8 ) * ù 弧度
∠B = 45 度 = ( 1 / 4 ) * ù 弧度
SIN( B ) = B / C
COS( B ) = A / C
TAN( B ) = B / A → B = A * TAN( B )
將公式建立在：技術(shù)指針( ○主圖 ●主圖疊加 )
公式名稱：KKK30
AA:=SUM( 1 , 0 ) - 1 ;
BB22: AA * TAN( ( 1 / 8 ) * 3.14159 ) ;
BB45: AA * TAN( ( 1 / 4 ) * 3.14159 ) ;
將公式建立在：技術(shù)指針( ○主圖 ●主圖疊加 )
公式名稱：KKK30.1
參數(shù)PARAM( N、45、0、80 )→預(yù)設(shè)為45度。
AA:=SUM( 1 , 0 ) - 1 ;
BB: AA* TAN( N * ( 3.14159 / 180 ) ) ;
0100--個股和大盤聯(lián)動K線
滲入“總報酬率”的觀念，就可畫出個股和大盤聯(lián)動K線。
公式名稱：KKK4
將公式建立在：技術(shù)指針 ( ○主圖 ●主圖疊加 )
參數(shù)PARAM( N，30，1，300 )
參數(shù)PARAM( M，1，0，1 )
AA:=SUM( 1 , 0 ) ;
BB:=IF( AA=1 , 1 , 0 ) ;
TT:=ISLASTBAR ;
DD:=BACKSET( TT=1 , N + 1 ) ;
EE:=BACKSET( TT=1 , N ) , LINETHICK0 ;
FF:=IF( DD>EE , 1 , 0 ) ;
GG:=IF( M=1 , FF , BB ) ;
PP:=BARSLAST( GG=1 ) , LINETHICK0; ;
X:=REF( INDEXC , PP ) ;
Y:=REF( CLOSE , PP ) ;
OO:( INDEXO / X ) * Y , LINETHICK0 ;
HH:( INDEXH / X ) * Y , LINETHICK0 ;
LL:( INDEXL / X ) * Y , LINETHICK0 ;
CC:( INDEXC / X ) * Y , LINETHICK0 ;
CC%:( INDEXC / X ) - 1 , LINETHICK0 ; { 基準日至今，大盤總報酬率 }
DC%:( CLOSE / Y ) - 1 , LINETHICK0 ; { 基準日至今，個股總報酬率 }
STICKLINE( CC>OO , HH , LL , 0.1 , 0 ) , COLORRED ;
STICKLINE( CC>OO , CC , OO , 7 , 1 ) , COLORRED ;
STICKLINE( CC<=OO , HH , LL , 0.1 , 0 ) , COLORCYAN ;
STICKLINE( CC<=OO , CC , OO , 7 , 0 ) , COLORCYAN ;
說明：
1. 從后面算來(第N+1日) 為基準日。例如，N=10；
2. 求算從后面算來(N日)→個股和大盤指數(shù)的聯(lián)動K線：
(每日大盤開盤指數(shù)/基準日當天的大盤收盤指數(shù))*基準日當天的收盤價
(每日大盤最高盤指數(shù)/基準日當天的大盤收盤指數(shù))*基準日當天的收盤價
(每日大盤最低盤指數(shù)/基準日當天的大盤收盤指數(shù))*基準日當天的收盤價
(每日大盤收盤指數(shù)/基準日當天的大盤收盤指數(shù))*基準日當天的收盤價
3. 公式的用意是：
以基準日為基準至今：大盤總報酬率多少，個股的總報酬率就多少。聯(lián)動在一起。
